確認くんのような情報を表示させるアプリを探しています。

ローカルのPCで動作して接続ポートも変更可能なものがいいです。

確認くん
http://www.ugtop.com/spill.shtml

回答の条件
  • 1人2回まで
  • 登録:2006/09/20 21:53:52
  • 終了:2006/09/23 18:27:51

回答(2件)

id:nil55 No.1

nil55回答回数452ベストアンサー獲得回数172006/09/21 00:03:34

ポイント42pt

このへんのフリーソフトが使えそうですね。

http://www.vector.co.jp/soft/win95/net/se220623.html?y

http://www.vector.co.jp/soft/winnt/net/se276466.html?y


一番簡単なのはルータへWeb Browserからログインして、

確認する方法があります。

あとは確認君みたいなWebSiteで確認できるものに診断君っていうのもあります。

http://taruo.net/e/

id:kenji

方向性はばっちりなんですけど、やはり表示情報がIPアドレスだけですので、もうちょっとブラウザが吐き出すであろう詳細な情報を表示してくれるといいですねー!

IPアシストはポートを3種類切り替えられて良かったのですが手動で設定できるともっとよかったです。

引き続き募集しますー!

2006/09/21 00:59:09
id:llusall No.2

llusall回答回数505ベストアンサー獲得回数612006/09/21 09:57:24

ポイント28pt

確認君のような環境変数を表示するVBスクリプトであれば、提供できますよ。


動作には「IIS」が必要です。

インストール方法はこちら...


1.以下、スクリプトを「chk.asp」というファイル名で「C:\Inetpub\wwwroot」に保存します。

<%@ Language=VBScript%>

<%Option Explicit%>

<HTML>

<HEAD>

</HEAD>

<BODY>

<%

    Dim SrvVal, SrvValComment

    Response.Write "<BR><BR>サーバー環境変数 -------------------------------------<BR>"

    For Each SrvVal In Request.ServerVariables

        SrvValComment = ""

        Select Case SrvVal

        Case "ALL_HTTP"

            SrvValComment = "クライアントから送信されたすべてのHTTPヘッダー(修正済み)"

        Case "ALL_RAW"

            SrvValComment = "クライアントから送信されたすべてのHTTPヘッダー"

        Case "APPL_MD_PATH"

            SrvValComment = "ISAPI用のアプリケーションのメタベースパスを取得する"

        Case "APPL_PHYSICAL_PATH"

            SrvValComment = "メタベースパスに対応する物理パスを取得する"

        Case "AUTH_PASSWORD"

            SrvValComment = "クライアント認証ダイアログに入力された値"

        Case "AUTH_TYPE"

            SrvValComment = "保護されたスクリプトのユーザ確認方法"

        Case "AUTH_USER"

            SrvValComment = "元の形式のままの認証ユーザ名"

        Case "CERT_COOKIE"

            SrvValComment = "クライアント証明書の一意のIDが文字列として返される"

        Case "CERT_FLAGS"

            SrvValComment = "クライアント証明書が存在するかどうかを取得する"

        Case "CERT_ISSUER"

            SrvValComment = "クライアント証明書のIssuerフィールド"

        Case "CERT_KEYSIZE"

            SrvValComment = "SecureSocketsLayer接続キーサイズのビット数"

        Case "CERT_SECRETKEYSIZE"

            SrvValComment = "サーバ-証明書秘密キーのビット数"

        Case "CERT_SERIALNUMBER"

            SrvValComment = "クライアント証明書のシリアル番号フィールド"

        Case "CERT_SERVER_ISSUER"

            SrvValComment = "サーバー証明書のIssuerフィールド"

        Case "CERT_SERVER_SUBJECT"

            SrvValComment = "サーバー証明書のSubjectフィールド"

        Case "CERT_SUBJECT"

            SrvValComment = "クライアント証明書のSubjectフィールド"

        Case "CONTENT_LENGTH"

            SrvValComment = "クライアントから提供されるコンテンツの長さ"

        Case "CONTENT_TYPE"

            SrvValComment = "HTTPクエリーのGET,POST,PUTなどのデータ型"

        Case "GATEWAY_INTERFACE"

            SrvValComment = "サーバーで使用するCGI仕様のリビジョン番号"

        Case "HTTPS"

            SrvValComment = "保護されたチャンネル経由かどうかを取得"

        Case "HTTPS_KEYSIZE"

            SrvValComment = "SecureSocketsLayer接続キーサイズのビット数"

        Case "HTTPS_SECRETKEYSIZE"

            SrvValComment = "サーバー証明書秘密キーのビット数"

        Case "HTTPS_SERVER_ISSUER"

            SrvValComment = "サーバー証明書のIssuerフィールド"

        Case "HTTPS_SERVER_SUBJECT"

            SrvValComment = "サーバー証明書のSubjectフィールド"

        Case "INSTANCE_ID"

            SrvValComment = "IISインスタンスのIDを文字形式で表したもの"

        Case "INSTANCE_META_PATH"

            SrvValComment = "要求に応答するIISのインスタンスのメタベースパス"

        Case "LOCAL_ADDR"

            SrvValComment = "要求を受け取ったサーバーのIPアドレスを取得する"

        Case "LOGON_USER"

            SrvValComment = "ユーザがログインしたWindowsNTアカウント"

        Case "PATH_INFO"

            SrvValComment = "クライアントから提供される捕捉パス情報"

        Case "PATH_TRANSLATED"

            SrvValComment = "PATH_INFOが変換されたもの"

        Case "QUERY_STRING"

            SrvValComment = "URL中のデータ部のクエリー情報"

        Case "REMOTE_ADDR"

            SrvValComment = "要求を出したリモートホストのIPアドレス"

        Case "REMOTE_HOST"

            SrvValComment = "要求を出したホストの名前"

        Case "REMOTE_USER"

            SrvValComment = "ユーザーから送信されたユーザ名"

        Case "REQUEST_METHOD"

            SrvValComment = "要求を出すために使われたメソッド"

        Case "SCRIPT_NAME"

            SrvValComment = "実行されたスクリプトへの仮想パス"

        Case "SERVER_NAME"

            SrvValComment = "サーバーのホスト名、DNSエイリアス、またはIPアドレス"

        Case "SERVER_PORT"

            SrvValComment = "要求が送られたポート番号"

        Case "SERVER_PORT_SECURE"

            SrvValComment = "保護されたポート上で要求が処理されたか取得する"

        Case "SERVER_PROTOCOL"

            SrvValComment = "要求情報プロトコルの名前とリビジョン番号"

        Case "SERVER_SOFTWARE"

            SrvValComment = "サーバーソフトウェアの名前とバージョン"

        Case "URL"

            SrvValComment = "URLのベース部分を示す"

        Case Else

            If Left(SrvVal,5) = "HTTP_" Then

                SrvValComment = Mid(SrvVal,6) & "に格納されている値"

            End If

        End Select

        Response.Write "---- " & SrvValComment & " ----<BR>"

        Response.Write SrvVal & "=[" & Request.ServerVariables(SrvVal) & "]<BR><BR>"


    Next

    Response.Write "-------------------------------------------------<BR>"

%>

</BODY>

</HTML>


2.ブラウザで、「http://localhost/chk.asp」を表示させます。


3.ポートの変更

     [インターネットインフォメーションサービス]を起動し、[既定のWEBサイト]を右クリックしてプロパティを表示。

     [WEBサイト]タブのTCPポートを変更します。

     ブラウザで、ポート番号をこのように指定して「http://localhost:8080/chk.asp」表示させます。(例:8080ポートに変更)

id:kenji

なるほどー!

JAVAスクリプトは見つけたのですがポートを変更する方法が分からなかったんです!

でもこれだとローカルの情報が表示されるので外部サーバーにスクリプトを置くかしないですね・・

2006/09/21 13:24:03

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません