こんにちは


Windows XP でデスクトップにfolderA、その中にExcel_file.xlsがあります
簡単なスクリプトを作って入力ボックスに、たとえばA-12234と入力すると
フォルダー名とファイル名がA-12234にリネームされるプログラムを作りたいのですが
具体的にどうすればよいでしょうか?

回答の条件
  • URL必須
  • 1人2回まで
  • 登録:2008/04/07 10:54:11
  • 終了:2008/04/07 13:27:38

ベストアンサー

id:Mook No.1

Mook回答回数1312ベストアンサー獲得回数3912008/04/07 13:17:32

ポイント60pt

vbs での実装例です。

適当なファイルに下記をコピーし、先頭の Constの部分を適切に変更後、vbs の拡張子のファイに保存して、

お試しください。


Option Explicit

Const srcFolderName = "FolderA"
Const srcFileName   = "Excel_file.xls"

Dim DesktopPath
DesktopPath = WScript.CreateObject("WScript.Shell").SpecialFolders("Desktop")

With CreateObject("Scripting.FileSystemObject")
'--- フォルダのチェック
    If Not .FolderExists( DesktopPath & "\" & srcFolderName ) Then
         WScript.Echo "デスクトップに" & srcFolderName & "がありません。"
         WScript.Quit
    End If

'--- ファイルのチェック
    If Not .FileExists( DesktopPath & "\" & srcFolderName & "\" &  srcFileName ) Then
         WScript.Echo "デスクトップに" & srcFolderName & "\" & srcFileName & "がありません。"
         WScript.Quit
    End If

'--- 新しい名前の入力
    Dim newName
    newName = InputBox( "新しいフォルダ名(ファイル名)を入力してください。" )

'---フォルダ、ファイルの変更
    .MoveFolder DesktopPath & "\" & srcFolderName, DesktopPath & "\" & newName
    .MoveFile   DesktopPath & "\" & newName & "\" &  srcFileName, DesktopPath & "\" & newName & "\" & newName & ".xls"
End With

http://www.whitire.com/vbs/

id:pzkpfwvi

ご回答ありがとうございます。

うまく動きました。

2008/04/07 13:26:32

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません