Excelで、指定したセルに画像や数値をＨＰから引っ張って来たいのですが、もし出来る方がおりましたらお願いします。

説明不足で申し訳ありませんでした。

前に回答したものはインターネットからソースを取得してメッセージボックスに表示する基本的な部分だけでした。

まず、シートにコマンドボタンをつけるには以下のような感じです。

http://sigoto.co.jp/excel/activex/lesson07/activex2.htm

同時に画像を表示させるためのイメージをシート上の好きなところに配置します。（名前はそのままImage1です）

ボタンを押したときにコードが実行されるようにするには、ボタンをダブルクリックして開くところに以下のコードをコピペします。

そして天気の画像をエクセルのブックと同じところに用意します。

画像は１～３０まで次のところにあります

http://image.weather.livedoor.com/img/icon/1.gif

Private Sub CommandButton1_Click()
    Dim ieo As Object
    Dim txt As String
    Dim pos As Long
    Dim pos2 As Long
    Dim tenki As String
    Dim kion As String
    Dim sp As Shape
    
    'IEオブジェクトの取得
    Set ieo = CreateObject("InternetExplorer.Application")
    ieo.Visible = False
    
    'ホームページを指定します
    ieo.NaviGate "http://weather.livedoor.com/area/20/72.html"

    '読みこまれるまでループさせます
    Do Until ieo.Busy = False
        Application.Wait Now + TimeValue("00:00:01")
    Loop
    
    'ＨＴＭＬソースを取得します
    txt = ieo.Document.Body.InnerHtml
    
    '取得したソースから天気と最高気温を探します。
    'この部分はホームページの変更によってうまく動作しなくなることがあります。
    pos = InStr(InStr(1, txt, "今日の天気", vbTextCompare), txt, "<small>", vbTextCompare) + 7
    pos2 = InStr(pos, txt, "<")
    tenki = Mid(txt, pos, pos2 - pos)
    pos = InStr(InStr(pos, txt, "最高気温", vbTextCompare), txt, "<small>", vbTextCompare) + 7
    pos2 = InStr(pos, txt, "<")
    kion = Mid(txt, pos, pos2 - pos)
    
    'イメージの大きさを画像の大きさに合わせます
    Image1.AutoSize = True
    
    '以下は天気によって条件分岐して画像を表示するところです
    '２つの場合しか作っていませんが３０個必要になります。
    Select Case tenki
        Case "晴れ"
            Image1.Picture = LoadPicture(ThisWorkbook.Path & "\1.gif")
            
        Case "曇時々雨"
            Image1.Picture = LoadPicture(ThisWorkbook.Path & "\10.gif")
    End Select
    
    '最高気温をA1セルに表示
    Range("A1").Value = kion
     
    Set ieo = Nothing
End Sub

ボタンを押すと、最高気温をA1セルに、天気を貼り付けたイメージに表示します。