エクセル操作についての質問です。複数のブックの、ヘッダやフッタ情報を一括で修正する方法があるかどうかを探しています。もしできるという場合は、具体的な手順があると助かります。よろしくお願いします!

回答の条件
  • 1人2回まで
  • 登録:2008/10/15 22:06:46
  • 終了:2008/10/15 23:37:56

回答(3件)

id:pahoo No.1

pahoo回答回数5960ベストアンサー獲得回数6332008/10/15 22:44:47

ポイント27pt

フリーソフト「Excel ヘッダ/フッタ一括設定アドイン」をお試しください。

id:ahsodik

ありがとうございました!

2008/10/15 23:37:14
id:ardarim No.2

ardarim回答回数892ベストアンサー獲得回数1422008/10/15 22:46:38

ポイント27pt

VBAマクロを使えばできます。

サンプル

Option Explicit

Sub test()

    Dim xlsFileNames As Variant
    Dim i As Long
    Dim bk As Workbook
    Dim sh As Worksheet
    
    ' 変更するブック名を指定する
    xlsFileNames = Array("c:\temp\aaa.xls", "c:\temp\bbb.xls")
    
    For i = LBound(xlsFileNames) To UBound(xlsFileNames)
        ' ファイルを開く
        Set bk = Workbooks.Open(xlsFileNames(i))
        
        ' 全てのシートにヘッダ・フッタを設定
        For Each sh In bk.Worksheets
            With sh.PageSetup
                .LeftHeader = "左ヘッダ文字列"
                .CenterHeader = "中央ヘッダ文字列"
                .RightHeader = "右ヘッダ文字列"
                .LeftFooter = "左フッタ文字列"
                .CenterFooter = "中央フッタ文字列"
                .RightFooter = "右フッタ文字列"
            End With
        Next sh
        
        ' 変更を保存してクローズ
        bk.Close True
    
    Next i
    
End Sub
id:ahsodik

ありがとうございました!

2008/10/15 23:37:26
id:oich No.3

oich回答回数18ベストアンサー獲得回数22008/10/15 22:52:20

ポイント27pt

VBAを使って良ければ以下に例を示します。

一口にヘッダやフッタ情報、といっても多岐にわたるので、あくまでヘッダやフッタの一部をいじるだけですが、

Sub 一括修正()
    Dim wb As Workbook
    Dim ws As Worksheet
    
    For Each wb In Application.Workbooks
        For Each ws In wb.Worksheets
            With ws.PageSetup
                .LeftHeader = "Left Header"
                .CenterHeader = "Center Header"
                .RightHeader = "Right Header"
                .LeftFooter = "Left Footer"
                .CenterFooter = "Center Footer"
                .RightFooter = "Right Footer"
            End With
        Next
    Next
End Sub

などとしてはいかがでしょうか?


また、VBAを使わずに、複数ブックのヘッダ・フッタを一括変更することはできないと思います。

上記は、開いているブックが対象なので、開いていないブックを対象にする場合にはブックを開く操作が別途必要になります。

id:ahsodik

ありがとうございました!

2008/10/15 23:37:35

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません