http://q.hatena.ne.jp/1239344679

http://q.hatena.ne.jp/1239702971
にて、最終的に下記のような、スバラシイ回答を
頂きました。

A2=INDIRECT("Sheet1!A"&INT((ROW()+23)/25)+1)&TEXT(OFFSET(Sheet1!$B$2,INT(((ROW()+23)/25)-1),MOD(INT(((ROW()+23)/5)),5)),"-#;;;-@")

B2=OFFSET(Sheet1!$G$2,INT(((ROW()+23)/25)-1),MOD((ROW()+3),5))


これに、空欄の場合の条件を入れたいです。

AAAAAAA,A,B,C,D,E,1,2,3,4,5
BBBBBBB,A,B,C,D,E,1,2,3,4,5
CCCCCCC,A,B,C,D,E,1,2,3,4,5

●A,B,C,D,Eには、一部、空があるが,1,2,3,4,5にも一部、空がある場合
 →ある物のみの組み合わせのみ表示

●A,B,C,D,Eは、全文、空で,1,2,3,4,5にも一部、空がある場合
 →ある物のみの組み合わせのみ表示
  AAAAAAA,1
  AAAAAAA,2
  AAAAAAA,3
  AAAAAAA,4
   ・
   ・
●A,B,C,D,Eは、有り、1,2,3,4,5は、空の場合
 →ある物のみの組み合わせのみ表示
  AAAAAAA-A
  のみ

こういう条件を入れることは可能でしょうか?

必ずイルカ賞を進呈させて頂きます。
よろしくお願いいたします。

回答の条件
  • URL必須
  • 1人2回まで
  • 登録:2009/04/16 19:24:08
  • 終了:2009/04/23 19:25:04

回答(1件)

id:SALINGER No.1

SALINGER回答回数3454ベストアンサー獲得回数9692009/04/17 11:16:13

ポイント60pt

最後の条件ですが、

A,B,C,D,Eは、有り、1,2,3,4,5は、空の場合
 →ある物のみの組み合わせのみ表示
  AAAAAAA-A
  のみ

1,2,3,4,5が空欄の場合表示しないのではなく、

AAAAAAA-A

AAAAAAA-B

AAAAAAA-C

AAAAAAA-D

AAAAAAA-E

と1個ずつ表示するということになるでしょうか。


その場合は作業列を作ることで可能です。

作業列を仮にD列とします。

D2の数式に以下とし、D5までコピー

=IF(OFFSET(Sheet1!$G$2,INT(((ROW()+23)/25)-1),MOD((ROW()+3),5))<>0,ROW(),1000)

D6の数式を以下として、下にコピー

=IF(OFFSET(Sheet1!$G$2,INT(((ROW()+23)/25)-1),MOD((ROW()+3),5))<>0,ROW(),IF(AND(SUM(D2:D5)=4000,INDIRECT("Sheet1!A"&INT((ROW()+23)/25)+1)&TEXT(OFFSET(Sheet1!$B$2,INT(((ROW()+23)/25)-1),MOD(INT(((ROW()+23)/5)),5)),"-#;;;-@")=INDIRECT("Sheet1!A"&INT((ROW()+23)/25)+1)&TEXT(OFFSET(Sheet1!$B$2,INT(((ROW()+23)/25)-1),MOD(INT(((ROW()+23)/5)),5)),"-#;;;-@")),ROW(),1000))


A2の数式を以下として、下にコピー

=INDIRECT("Sheet1!A"&INT((SMALL(D:D,ROW()-1)+23)/25)+1)&TEXT(OFFSET(Sheet1!$B$2,INT(((SMALL(D:D,ROW()-1)+23)/25)-1),MOD(INT(((SMALL(D:D,ROW()-1)+23)/5)),5)),"-#;;;-@")

B2の数式を以下として、下にコピー

=OFFSET(Sheet1!$G$2,INT(((SMALL(D:D,ROW()-1)+23)/25)-1),MOD((SMALL(D:D,ROW()-1)+3),5))

C2の数式を以下として、下にコピー

=OFFSET(Sheet1!$B$2,INT(((SMALL(D:D,ROW()-1)+23)/25)-1),MOD(INT(((SMALL(D:D,ROW()-1)+23)/5)),5))&""


非常に長い数式ですが、やっていることは作業列の条件を満たす行にその行数を、満たさない場合に十分大きな数を(ここでは1000)が表示されるようにしています。

A2、B2、C2の数式は、前回の質問の式とほとんど同じで、Row()をSMALL(D:D,ROW()-1)に置き換えただけです。

http://q.hatena.ne.jp/

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません