(解決時には1名様に500ptお支払いします)

http://q.hatena.ne.jp/1242871311のつづきなのですが、
無理をすみません。txtファイルがある場合にはMsgBoxで
バックアップに失敗しました と表示し、txtファイルが無い場合
には バックアップに成功しました とMsgBoxで表示させたいの
ですが、このVBSをお願いできますでしょうか。よろしくお願いします。

回答の条件
  • 1人2回まで
  • 登録:2009/05/21 15:15:07
  • 終了:2009/05/21 16:18:34

ベストアンサー

id:fester No.1

fester回答回数124ベストアンサー獲得回数202009/05/21 15:35:38

ポイント60pt
Option Explicit
Const FILENAME = "C:\Documents and Settings\MACHI\デスクトップ\DimsqlAsNewStringBuilder.txt"
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Const TITLE = "ARCServeのバックアップ"

Dim fso
Set fso = WScript.CreateObject("Scripting.FileSystemObject") 

If fso.FileExists(FILENAME) = False Then
    MsgBox "バックアップに成功しました", vbInformation, TITLE
    Set fso = Nothing
    WScript.Quit
End If

Dim file
Set file = fso.OpenTextFile( FILENAME, ForReading ) 

Dim strALL
strALL = file.ReadAll 
file.Close 

Set file = Nothing
Set fso = Nothing

Dim aryLines
aryLines = Split( strALL, vbCrLf ) 

Dim message, i
For i = UBound(aryLines) To 0 Step -1
    message = Trim(aryLines(i))
    If Len(message) > 0 Then
        Exit For
    End If
Next

MsgBox "バックアップに失敗しました" & vbCrLf & vbCrLf & message, vbCritical, TITLE


こちらでいかがでしょうか

id:meichi

たびたびありがとうございました。m(_ _)m

確認しました。これでおわります。お言葉に甘えて通常のポイントの

支払でさせていただきます。

2009/05/21 16:18:10
  • id:fester
    先ほどポイントをたくさんいただき、ありがとうございました。なので今回はポイントは普通でかまいませんよ。

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません