ちょっと説明しにくいのですが・・・

http://dummy/

１つのフォルダに

・目的のファイル（複数可能 名前なんでも）.txt

・ラベル名の情報のファイル "label.txt"

・以下を".vbs"をつけて保存したもの

を置いて、vbsファイルをダブルクリックすると、後ろに"_out.txt"のついたファイルが出来上がります。

set fso=createobject("scripting.filesystemobject")
set she=createobject("wscript.shell")
set labels=createobject("scripting.dictionary")
set regex=new regexp
regex.global=true

set_label "label.txt"

for each f in fso.getfolder(".").files
	if f.name<>"label.txt" and right(f.name,4)=".txt" then
		exec f.name
	end if
next

sub set_label(fname)
	set infile=fso.opentextfile(fname)
	regex.pattern="(.*)\t(.*)"
	do while not infile.atendofstream
		line=infile.readline
		set pair=regex.execute(line)(0)
		labels.add pair.submatches(0), pair.submatches(1)
	loop
end sub

sub exec(fname)
	set infile=fso.opentextfile(fname)
	set outfile=fso.createtextfile(fname & "_out.txt")
	regex.pattern="([0-9]+):"
	do while not infile.atendofstream
		line=infile.readline
		for each hit in regex.execute(line)
			hit=hit.submatches(0)
			line=replace(line, hit & ":", labels(hit) & ":")
		next
		outfile.writeline line
	loop
end sub