エクセルのセル内の文字列をマクロを使ってmicrosoft　wordの要約機能で自動要約するためのプログラムを探しています。

ActiveDocument.AutoSummarize メソッドで要約します。

こんな感じでしょうか。

Option Explicit

Public Sub 要約実行()
    Const wdNewBlankDocument As Integer = 0
    Const wdSummaryModeCreateNew As Integer = 3
    '文書全体の長さに対する要約の長さの割合 (%)。数値が大きいほど詳細な内容が要約に含められます。
    Const AUTO_SUMMARIZE_LENGTH As Integer = 25
    
    Dim wk As String
    Dim objWord
    Set objWord = CreateObject("Word.Application")  'ワード起動
    objWord.Visible = False 'ワード非表示
    objWord.Documents.Add DocumentType:=wdNewBlankDocument
    
    Application.ScreenUpdating = False
    Cells(1, 1).Activate
    
    Do Until ActiveCell.Value = ""
        objWord.Selection.HomeKey
        objWord.Selection.TypeText Text:=ActiveCell.Value
        objWord.ActiveDocument.AutoSummarize Length:=AUTO_SUMMARIZE_LENGTH, Mode:=wdSummaryModeCreateNew, UpdateProperties:=False
        objWord.ActiveDocument.Select
        wk = objWord.Selection.Text
        If wk = vbCr Then
            '要約できない場合はそのままセット
            ActiveCell.Offset(0, 1).Value = ActiveCell.Value
        Else
            '要約を貼り付け
            ActiveCell.Offset(0, 1).Value = wk
        End If
        objWord.ActiveDocument.Close False
        objWord.ActiveDocument.Select
        objWord.Selection.Text = ""
        ActiveCell.Offset(1, 0).Activate
    Loop
    
    
    Cells(1, 1).Activate
    Application.ScreenUpdating = True
    
    objWord.Quit False
    Set objWord = Nothing
    
End Sub

※要約率は、

Const AUTO_SUMMARIZE_LENGTH As Integer = 25

を調整してください。

※ある程度の文章でないと要約できないのではないでしょうか？

　　　10文字の文字列等では無理のような・・・