excel、セルに左から、岡山(18ポイント)、(3ポイントの無色の文字)、太郎(12ポイント)これを結合して、

次のセルに{岡山 太郎(太郎は小さく)}になるように入れたい
 関数で出来ますか、マクロではどうですか?

回答の条件
  • 1人1回まで
  • 13歳以上
  • 登録:2011/03/25 07:24:16
  • 終了:2011/03/25 13:50:12

回答(2件)

id:SALINGER No.1

SALINGER回答回数3454ベストアンサー獲得回数9692011/03/25 08:10:49

ポイント50pt

関数だと文字のフォントを変えられなく、条件付き書式はセル単位でしか変更できないのでマクロになります。

A列に岡山、B列に太郎があり、C列に岡山太郎を書き出すコードです。

間の無職の文字は3ポイントの半角スペースでよろしいかと思います。

Sub Macro()
    Dim i As Long
    Dim lastRow As Long
    
    lastRow = Cells(Rows.Count, "A").End(xlUp).Row
    
    For i = 1 To lastRow
        If Cells(i, "A").Value <> "" And Cells(i, "B").Value <> "" Then
            Cells(i, "C").Value = Cells(i, "A").Value & " " & Cells(i, "B").Value
            Cells(i, "C").Characters(Start:=1, Length:=Len(Cells(i, "A").Value)).Font.Size = 18
            Cells(i, "C").Characters(Start:=Len(Cells(i, "A").Value) + 1, Length:=1).Font.Size = 3
            Cells(i, "C").Characters(Start:=Len(Cells(i, "A").Value) + 2, Length:=Len(Cells(i, "B").Value)).Font.Size = 12
        Else
            Cells(i, "C").Value = ""
        End If
    Next i
End Sub
id:mitsueda

有難う御座いました、でも私にはちょっと

2011/03/25 13:49:12
id:taknt No.2

きゃづみぃ回答回数13538ベストアンサー獲得回数11982011/03/25 09:18:49

ポイント50pt

指定した開始セルアドレスから 左に3セル分を結合し、それぞれ指定されているフォントのサイズにします。

Sub 結合()
    
    開始セルアドレス = "A1"
    
    
    r = Range(開始セルアドレス).Row
    c = Range(開始セルアドレス).Column
    
    a1 = Cells(r, c)
    a2 = Cells(r, c + 1)
    a3 = Cells(r, c + 2)
    f1 = Cells(r, c).Font.Size
    f2 = Cells(r, c + 1).Font.Size
    f3 = Cells(r, c + 2).Font.Size
    
    Cells(r, c + 1) = ""
    Cells(r, c + 2) = ""
    
    Range(Cells(r, c), Cells(r, c + 2)).MergeCells = True
    Cells(r, c) = a1 & a2 & a3
    
    Cells(r, c).Characters(Start:=1, Length:=Len(a1)).Font.Size = f1
    
    Cells(r, c).Characters(Start:=Len(a1) + 1, Length:=Len(a2)).Font.Size = f2
    
    Cells(r, c).Characters(Start:=Len(a1) + Len(a2) + 1, Length:=Len(a3)).Font.Size = f3
 
End Sub

id:mitsueda

有難う御座いました、でも私にはちょっと

2011/03/25 13:49:34

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません