vbsの質問です

hoge フォルダの中に
hoge
|-01
|-02
|-03
|-04
|-・
|-・
|-・
と数字の連番の名前がついたフォルダが入っています
その各数字フォルダの中にa.htmlが入っています。
その各a.htmlの中の 末尾にある同じ文章をぶち込みたいです
その場合どの様にvbsを組めばよろしいでしょうか、教えてください。
よろしくお願いします。

回答の条件
  • 1人1回まで
  • 13歳以上
  • 登録:2014/12/02 12:39:04
  • 終了:2014/12/05 10:55:34

ベストアンサー

id:a-kuma3 No.1

a-kuma3回答回数4412ベストアンサー獲得回数18032014/12/02 13:16:50

ポイント300pt

こんな感じになります。

targetFolderName = "D:\test\hoge"   ' ※ hoge フォルダのパス

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)
For Each folder In targetFolder.SubFolders
    For Each f In folder.Files
        If f.Name = "a.html" Then
            Set target = fs.OpenTextFile(f.Path, 8)   ' for append

            target.WriteLine "----------------"
            target.WriteLine "追加する文章"
            target.WriteLine "----------------"

            target.Close

        End If
    Next
Next




追記です。

すみません、UTF8のテキストファイルに書き込んだら
追加する文章 という文字が文字化けしてしまいました
文字化けせずにするにはどうすればいいでしょうか?

UTF-8 の場合には、以下のようにしてください。

Set ado = WScript.CreateObject("adodb.stream")
ado.Type = 2
ado.Charset = "UTF-8"

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)
For Each folder In targetFolder.SubFolders
    For Each f In folder.Files
        If f.Name = "a.html" Then

            ado.Open
            ado.LoadFromFile f.Path
            txt = ado.ReadText
            ado.Close

            ado.Open
            ado.Position = 0
            ado.WriteText txt
            ado.WriteText "----------------" & vbCrLf
            ado.WriteText "追加する文章"     & vbCrLf
            ado.WriteText "----------------" & vbCrLf
            ado.SaveToFile f.Path, 2
            ado.Close

        End If
    Next
Next

Set ado = Nothing
他1件のコメントを見る
id:a-kuma3

回答に追記しました。

2014/12/02 17:35:24
id:fashudifhajs

ありがとうございました!

2014/12/02 18:06:19

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません