2つのExcelのブックがあります。

ブックBのB列には、

※(行目)|文字列

1|あいうえお
2|あいうえお
3|あいうえお
4|かきくけこ
5|かきくけこ
6|かきくけこ
7|(空白セル)
8|さしすせそ
9|さしすせそ
10|たちつてと



のようなデータが。
ブックAのZ列には、

1|あいうえお
2|あいうえお
3|(空白セル)
4|かきくけこ
5|かきくけこ
6|さしすせそ
7|さしすせそ
8|さしすせそ
9|たちつてと



のようなデータが入ってます。
この状況で、重複や空白セルは無視し、ブックB・B列の“最後の該当データ”(上記の場合3行目、6行目、9行目)と、ブックA・Z列の“最初の該当データ”(上記の場合1行目、4行目、6行目、9行目)が一致した時。

ブックB・B列“最後の該当データ”のK列のデータをコピーして。(①)
ブックA・Z列“最初の該当データ”から右に13(AM列)、下に1セル移動した箇所のセルに、①の文字列を貼り付けたいのです。

そんな処理をマクロでもし出来れば助かるのですが…よろしくお願いします。

回答の条件
  • 1人10回まで
  • 13歳以上
  • 登録:2016/03/21 14:47:17
  • 終了:2016/03/23 06:09:19

ベストアンサー

id:a-kuma3 No.1

a-kuma3回答回数4363ベストアンサー獲得回数18002016/03/21 16:27:03

ポイント1700pt

以下のコードをブックA の標準モジュールに貼り付けて、サブルーチンの先頭の変数 ref_book_filename にブックB のファイル名をフルパスで設定してください。
そして、set_data2 サブルーチンを実行してください。

Sub set_data2()
    ref_book_filename = "d:\foo\bar.xlsx"   ' 参照先の Book (フルパス)
    ref_key_column = 2                      ' B列
    ref_value_column = 11                   ' K列
    search_column = 26                      ' Z列
    write_column = search_column + 13       ' AM列

    Set this_book = ActiveWorkbook
    Set ref_book = Workbooks.Open(ref_book_filename)
    this_book.Activate

    ' 別シートの値を読み込む
    Set ref_sheet = ref_book.Sheets(1)  ' ひとつめのシート
    last_row = ref_sheet.Cells(Rows.Count, ref_key_column).End(xlUp).Row

    Set Map = CreateObject("Scripting.Dictionary")
    For r = last_row To 1 Step -1
        Set cell = ref_sheet.Cells(r, ref_key_column)
        If Not IsEmpty(cell) And Not cell.Value = "" Then
            If Not Map.Exists(cell.Value) Then
                Map.Add cell.Value, ref_sheet.Cells(r, ref_value_column).Value
            End If
        End If
        DoEvents
    Next

    ref_book.Close
    Set ref_book = Nothing

    ' 対象シートから探して、値を書き込む
    last_row = Cells(Rows.Count, search_column).End(xlUp).Row
    For Each Key In Map.keys
        For r = 1 To last_row
            If Cells(r, search_column).Value = Key Then
                Cells(r + 1, write_column).Value = Map.Item(Key)
                Exit For
            End If
            DoEvents
        Next
    Next

    Set Map = Nothing

End Sub

前の質問では、ブックA の Z列を確認する際には部分一致ということでしたが、今回は明記されていないので完全一致で引き当ててます。

id:moon-fondu

ありがとうございます、うまく貼り付けすることが出来ました!

2016/03/23 06:09:01

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません