2つのExcelのブックがあります。

ブックBのJ列には、空白セルとデータが混じってます。
※(行目)|文字列

1|あいうえお
2|(空白セル)
3|(空白セル)
4|かきくけこ
5|(空白セル)
6|さしすせそ


ブックAのR列には、

1|(空白セル)
2|あいうえおについて
3|あいうえおです
4|かきくけこの発声練習
5|かきくけこについて
6|(空白セル)
7|さしすせその勉強
8|(空白セル)
9|さしすせそについて


のようなデータが入ってます。
ブックBのJ列の空白セルは無視し、ブックB・J列のデータのあるセルの文字列(ブックB-①とします)を1つずつ、ブックAのR列にあるかどうか探します。(ブックA・R列のセルと完全一致しなくても可)

そして一致した場合は。

“最初の該当データ”から右に28(AT列)、下に1セル移動した箇所のセル(この場所をA-①とします)に。
ブックB-①の文字列ではなく…ブックB-①から右に2セル移動したセルから横に3セル(L列~N列)分をコピーします(B-②)。

そしてこのB-②を、A-①に貼り付けるという。
処理を、マクロ等で実現したいのです。ご教授よろしくお願い致します。

回答の条件
  • 1人10回まで
  • 登録:2017/09/02 23:52:23
  • 終了:2017/09/05 07:17:33

ベストアンサー

id:a-kuma3 No.1

a-kuma3回答回数4605ベストアンサー獲得回数19432017/09/03 10:32:56

ポイント2000pt

こんな感じで。

Sub set_data()
    ref_book_filename = "d:\foo\bar.xlsx"   ' 参照先の Book (フルパス)
    ref_column = 10                         ' J列
    search_column = 18                      ' R列
    write_column = search_column + 28       ' AT列

    Set this_book = ActiveWorkbook
    Set ref_book = Workbooks.Open(ref_book_filename)
    this_book.Activate

    ' 別シートの値を読み込む
    Set ref_sheet = ref_book.Sheets(1)  ' ひとつめのシート
    last_row = ref_sheet.Cells(Rows.Count, ref_column).End(xlUp).Row

    Set Map = CreateObject("Scripting.Dictionary")
    For r = 1 To last_row
        Set cell = ref_sheet.Cells(r, ref_column)
        If Not IsEmpty(cell) And Not cell.Value = "" Then
            If Not Map.Exists(cell.Value) Then
                Map.Add cell.Value, r
            End If
        End If
        DoEvents
    Next

    ' 対象シートから探して、値を書き込む
    last_row = Cells(Rows.Count, search_column).End(xlUp).Row
    For Each Key In Map.keys
        Debug.Print Key
        For r = 1 To last_row
            If InStr(Cells(r, search_column).Value, Key) > 0 Then
                rr = Map.Item(Key)
                ref_sheet.Range(ref_sheet.Cells(rr, ref_column + 2), ref_sheet.Cells(rr, ref_column + 4)).Copy _
                    Cells(r + 1, write_column)
                Exit For
            End If
            DoEvents
        Next
    Next

    ref_book.Close
    Set ref_book = Nothing

    Set Map = Nothing

End Sub

ブックA の標準モジュールに上記のコードを追加して、set_data() サブルーチンを実行。
前の質問と書き込み先(AT列)が被ってますが、大丈夫ですか?

id:moon-fondu

はい、大丈夫です、うまくいきました!
ありがとうございました(^^♪

2017/09/05 07:17:15

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません