人力検索はてな
モバイル版を表示しています。PC版はこちら
i-mobile

パワーポイント2007について教えてください。パワーポイント2007で音楽を再生したいと思っています。

やりたいことは、例えばスライドショーが20枚あるとします。

スライドショー1枚目で音楽をA.mp3を再生します。1?10枚目まではずっと同じ音楽を流しっぱなしにしたいです。つまり、2枚目にスライドショーが移動しても、音楽は途切れずに、流れっぱなしにしたいです。

スライドショー11枚目にさしかかった時に、B.mp3を再生させて、20枚目までずっと流しっぱなしにしたいです。

このような事は可能でしょうか?可能であれば、やり方を教えてください。

●質問者: akaired
●カテゴリ:コンピュータ インターネット
✍キーワード:MP3 スライドショー パワーポイント 再生 音楽
○ 状態 :終了
└ 回答数 : 1/1件

▽最新の回答へ

1 ● Silvanus
●100ポイント ベストアンサー

もし、PowerPointでVisual Basic for Applicationをお使いになったことがなく、

以下の説明が理解できない場合はその旨コメントでお知らせ下さい。説明を追加いたします。

?????

以下に説明する方法にはいろいろ制限があります。

・MP3ファイルは使用できない。WAVファイルならOK。

・BGMのリピートはできない。

・スライドショーの開始は、マクロ(StartSlideShowWithBGM)を実行して行なう。

・スライドショーを中断した場合は、マクロ(StopBGM)でBGMを停止する。

改善可能な点がないかどうか継続して検討しますので

「何とかして解決して欲しい」不満点がありましたら、コメント下さい。

???

クラスモジュール"Class1"

Option Explicit

Private Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _

(ByVal strCommand As String, _

ByVal strReturnString As String, _

ByVal cchReturn As Long, _

ByVal hwndCallback As Long) As Long

Public WithEvents AppEvent As Application

Const intSldPosBGMChg As Integer = 11

Const strFilePath1 As String = "D:\Music\AlwaysTogether.wav"

Const strFilePath2 As String = "D:\Music\ThankYouAll.wav"

Private Sub AppEvent_SlideShowBegin(ByVal Wn As SlideShowWindow)

Dim lngRtnCd As Long

lngRtnCd = mciSendString("play " & strFilePath1 & " from 1", "", 0, 0)

End Sub

Private Sub AppEvent_SlideShowNextSlide(ByVal Wn As SlideShowWindow)

Dim intSlidePos As Integer

Dim lngRtnCd As Long

intSlidePos = Wn.View.CurrentShowPosition

If intSlidePos = intSldPosBGMChg Then

lngRtnCd = mciSendString("stop " & strFilePath1, "", 0, 0)

lngRtnCd = mciSendString("play " & strFilePath2 & " from 1", "", 0, 0)

End If

End Sub

Private Sub AppEvent_SlideShowEnd(ByVal Pres As Presentation)

Dim lngRtnCd As Long

lngRtnCd = mciSendString("stop " & strFilePath2, "", 0, 0)

Set Module1.MyObject.AppEvent = Nothing

End Sub

???

標準モジュール

Option Explicit

Private Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _

(ByVal strCommand As String, _

ByVal strReturnString As String, _

ByVal cchReturn As Long, _

ByVal hwndCallback As Long) As Long

Public MyObject As New Class1

Const strFilePath1 As String = "D:\Music\AlwaysTogether.wav"

Const strFilePath2 As String = "D:\Music\ThankYouAll.wav"

Sub BeginSlideShowWithBGM()

Set MyObject.AppEvent = Application

ActivePresentation.SlideShowSettings.Run

End Sub

Sub StopBGM()

Dim lngRtnCd As Long

lngRtnCd = mciSendString("stop " & strFilePath1, "", 0, 0)

lngRtnCd = mciSendString("stop " & strFilePath2, "", 0, 0)

End Sub

関連質問


●質問をもっと探す●



0.人力検索はてなトップ
8.このページを友達に紹介
9.このページの先頭へ
対応機種一覧
お問い合わせ
ヘルプ/お知らせ
ログイン
無料ユーザー登録
はてなトップ