こんな感じ｡

 data = "ﾃｽﾄ 第123回"
 Set re = CreateObject("VBScript.RegExp")
 re.Pattern = "^(.+)[  ]*第[0-9]+回"
 re.Global = True
 Set matches = re.Execute(data)
 result = matches(0).SubMatches(0)  ' これが "ﾃｽﾄ" になってます

正規表現ｵﾌﾞｼﾞｪｸﾄというものを使います｡
re.Pattern に設定している文字列が正規表現です｡
ちょっと分かりにくいですが､[ ] の中には､半角の空白と全角の空白が続けて書いてあります｡

data = "お試しｺｰﾄﾞのﾃｽﾄ 第123回"
Set re = new RegExp  ' VBA と､ここだけ違う｡
re.Pattern = "^(.+)[  ]*第[0-9]+回"
re.Global = True
Set matches = re.Execute(data)
result = matches(0).SubMatches(0)  ' これが "ﾃｽﾄ" になってます

WScript.echo result

まだ動かしてないのですが､勉強がてらした3行が何をやってるか教えていただくと幸いです(ぐｰぐる先生に聞いてみましたがどうもよくわからない｡｡)

おっちょこちょいな回答を書いた手前､分かる範囲であれば､何でも答えます (^^;

＞re.Global = True

これは､Execute ﾒｿｯﾄﾞで､指定した正規表現が一致する個所を見つけたときに､
それ以降も検索するかどうかの指定です｡
Global = True だと､一致するﾊﾟﾀｰﾝが複数あるときに､全て探そうとします｡
今回の場合には､True でも False でも､動作に違いが無いんですが､
対象の文字列が "お試しｺｰﾄﾞのﾃｽﾄ 第123回 (関東支部開催 第25回" のように､
複数繰り返されているような場合に､Execute ﾒｿｯﾄﾞの戻りの内容が変わってきます｡

＞Set matches = re.Execute(data)

正規表現 re.Pattern が表す内容を､文字列 data に対して実行して､検索した結果を返します｡
検索結果は､Matches というｺﾚｸｼｮﾝになっています｡

＞result = matches(0).SubMatches(0) ' これが "ﾃｽﾄ" になってます

Execute ﾒｿｯﾄﾞの戻り値である Matches ｺﾚｸｼｮﾝは､文字列 data を検索した結果が入ってます｡
Matches ｺﾚｸｼｮﾝは､Match ｵﾌﾞｼﾞｪｸﾄのｺﾚｸｼｮﾝです｡
先程の､Global ﾌﾟﾛﾊﾟﾃｨが True だと､要素数が2以上になる可能性があります｡

Match ｵﾌﾞｼﾞｪｸﾄが､検索して一致した結果を表しています｡
Match ｵﾌﾞｼﾞｪｸﾄは､以下のﾌﾟﾛﾊﾟﾃｨと､ｺﾚｸｼｮﾝを持ちます｡

• FirstIndex ﾌﾟﾛﾊﾟﾃｨ … 一致した箇所の先頭の文字位置
• Length ﾌﾟﾛﾊﾟﾃｨ … 一致した箇所の長さ
• Value ﾌﾟﾛﾊﾟﾃｨ … 一致した文字列
• SubMatches ｺﾚｸｼｮﾝ … 正規表現の () に相当する部分に一致した文字列のｺﾚｸｼｮﾝ

正規表現の説明からした方が良いでしょうね｡
"^(.+)[ ]*第[0-9]+回" という正規表現を分解すると､

この正規表現を "お試しｺｰﾄﾞのﾃｽﾄ 第123回" に対して実行すると､全体がﾏｯﾁします｡
一回だけ見つけられるので､matches の要素数は 1 で､そのひとつ目の Match では､

• FirstIndex … 文字列の先頭から一致してますから､0 になります｡
• Length … 文字列全体が一致しているので 14 です(ﾊﾞｲﾄ数ではなく､文字数)｡
• Value … 文字列全体が一致しているので､"お試しｺｰﾄﾞのﾃｽﾄ 第123回" になります｡

ここで､正規表現に () でくくった "(.+)" があるので､そこに一致する部分が SubMatches ｺﾚｸｼｮﾝで取得できます｡
() でくくった表現はひとつしかないので､SubMatches の要素数は1です｡
そのひとつ目の内容は､文字列の先頭から､空白に続く｢第｣の前までが該当するので､
matches(0).SubMatches(0) は "お試しｺｰﾄﾞのﾃｽﾄ" になります｡

もし複数の条件を追加しようとする場合は
｢Set re｣の部分を｢re1｣｢re2｣｢re3｣として
同じような処理を回すみたいなのが一番効率がいいのでしょうか
ちなみに追加したいのは以下です｡


･第XX話
･#XX
･(XX)
･(XX)
･XX話

※ｽﾍﾟｰｽの条件も1つ目と同じです｡
※XXは数字で大文字も含む

｢数字で大文字｣というのは､全角のことですよね｡
こんな感じになります｡

Sub re_test (data, re)
 Set matches = re.Execute(data)
 result = matches(0).SubMatches(0)  ' これが "ﾃｽﾄ" になってます
 WScript.echo "'" & result & "' <-- '" & data & "'"
end sub

Set re = new RegExp
re.Pattern = "^([^  ]+)[  ]+[第#((]?[0-90-9]+[回話))]?"

re_test "お試しｺｰﾄﾞのﾃｽﾄ 第123話" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ #123 あああ" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ  (123)" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ (123)" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ 123話" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ 第456話" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ #456 あああ" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ  (456)" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ (456)" , re
re_test "お試しｺｰﾄﾞのﾃｽﾄ 456話" , re

正規表現を変えたのと､動作確認の部分をｻﾌﾞﾙｰﾁﾝにしただけです｡

追加された条件と合わせて考えると､数字の部分と､その前後に一文字付くかもしれない､ということになります｡

数字の部分には､全角も含むということなので､[0-90-9]+ としました｡

数字の前に付く文字は､四つあって､そのうちのどれかということで [第#((]? です｡
"?" は､直前の表現が0回か1回､という意味です｡
"第?" で､第がひとつ付くか､付かないか､という意味で､これを [ ] で複数指定してます｡

数字の後に付く文字も､同様に [回話))]? としてます｡

正規表現を使います
vbsなら下記のような具合です

Option Explicit

' ﾃﾞｰﾀ準備
Dim s1, s2
s1 = "ﾃｽﾄ 第195回  "
s2 = ""

' 正規表現による置換
Dim r
Set r = New RegExp
r.Pattern = "(.*)[  ]*第[0-90-9]+回.*"
s2 = r.Replace(s1, "$1")

' 結果出力
WScript.Echo "[" & s2 & "]"

前後の空白を消せたかどうかの確認のため､結果出力では[角括弧]でくくってます

ｽｸﾘﾌﾟﾄを組んでみました｡
元の文字列を変数sourに入れると､変数destに切り出したい文字列が入るようになっています｡
もし元の文字列がﾙｰﾙ通りでないと､destは空になります｡

Option Explicit

Dim sour, dest
Dim re, remat

sour = "ﾃｽﾄ  第123回"  '元の文字列

'正規表現ﾊﾟﾀｰﾝの設定
Set re = new RegExp
re.IgnoreCase = True
re.Global = True
re.pattern = "^(.+)([  ]+第[0-9]{1,3}回)$"
Set remat = re.Execute(sour)

'抽出
dest = ""
if (remat.Count = 1) Then
 dest = remat(0).SubMatches(0)
End If

Set re = Nothing

MsgBox dest  '表示