人力検索はてな
ﾓﾊﾞｲﾙ版を表示しています｡PC版はこちら
i-mobile
あるﾃｷｽﾄﾌｧｲﾙに設定を追加するVBScriptの作成を考えております｡


?※ﾎﾟｲﾝﾄは基本的にﾍﾞｽﾄｱﾝｻｰの方にすべて配分させていただきますが､内容によりその他の方にも配分します｡


以下のような構成のﾃｷｽﾄﾌｧｲﾙがあり､ｾｸｼｮﾝ毎(<1TEST1>等)の設定項目(DATA1)に値を追加する
VBScriptの作成を考えております｡以下2点の仕様に対応するVBScriptのｻﾝﾌﾟﾙｽｸﾘﾌﾟﾄを作成いただけないしょうか
よろしくお願いいたします｡


??設定する際の注意点として､ｾｸｼｮﾝ毎(<1TEST1>等)に設定項目(DATA1)を上から精査し､
? ?設定が入力されていない部分(｢<1TEST1>｣であれば｢DATA4 = ｣)に設定を追加したいです｡

??また､追記する際に｢DATA4 = ｣及び｢DATA5 = ｣の項目が既に別の値が入力されていた場合は｢DATA6 = ｣を追加して
? 設定を追加するようなものにしたいです｡


仕様の?､?の例につきましてはｺﾒﾝﾄに書かせていただきます｡
●質問者: gocnia3
●ｶﾃｺﾞﾘ:ｺﾝﾋﾟｭｰﾀ ｲﾝﾀｰﾈｯﾄ
○ 状態 :終了
└ 回答数 : 1/1件
▽最新の回答へ
▽1 ● Mook
●2000ﾎﾟｲﾝﾄ ﾍﾞｽﾄｱﾝｻｰ

一応書かれている仕様は網羅していると思いますが､
過不足があれば､ｺﾒﾝﾄと下さい｡

実行方法は VBS ﾌｧｲﾙに二つのﾃﾞｰﾀﾌｧｲﾙをﾄﾞﾛｯﾌﾟするか､
ｺﾏﾝﾄﾞで

>CScript AppendData.vbs data.txt append.dat

として実行してください｡

??????????????????????????????????????
改訂版です｡

以下変更しました
先頭に書かれたｾｸｼｮﾝをﾏｽﾀｰ位置として､指定しています｡

想定ﾃﾞｰﾀです｡
元ﾃﾞｰﾀ：data.txt

<1TEST1> 'ｾｸｼｮﾝ1

<2TEST2> 'ｾｸｼｮﾝ1
DATA1 = GGG1
DATA2 = GGG2
DATA3 = GGG3
DATA4 = GGG9
DATA5 = 

<3TEST3> 'ｾｸｼｮﾝ1
DATA1 = FFF1
DATA2 = FFF2
DATA3 = FFF3
DATA4 = FFF9


追加ﾃﾞｰﾀ:append.dat

<2TEST2> <= MASTER_2用追加ﾃﾞｰﾀ
<1TEST1> <= 1用追加ﾃﾞｰﾀ
<3TEST3> <= 3用追加ﾃﾞｰﾀ


ｽｸﾘﾌﾟﾄ：AppendData.vbs

'================================================================
'// *.txt[ SourceFileExtention で拡張子を設定] ﾌｧｲﾙに
'// *.dat[ AppendFileExtention で拡張子を設定] ﾌｧｲﾙの内容を追加する
'---------------------------------------------------------------
'// *.dat[設定可能] の書式は
'//     <ｾｸｼｮﾝ名1> <= ﾃﾞｰﾀ1 先頭で記述したｾｸｼｮﾝが主ﾃﾞｰﾀ
'//     <ｾｸｼｮﾝ名2> <= ﾃﾞｰﾀ2
'//     <ｾｸｼｮﾝ名3> <= ﾃﾞｰﾀ3
'---------------------------------------------------------------
'// 結果は元のﾌｧｲﾙに時間情報をつけた次のﾌｧｲﾙ名として保存する
'//    元ﾌｧｲﾙ名_YYYYMMDD_HHMMSS.txt
'---------------------------------------------------------------
'// 改定：先頭で指定したｾｸｼｮﾝと同じ位置に全体を設定するよう変更
'//    設定先が空で無い場合はｴﾗｰ
'================================================================
Option Explicit

'--------------------------------------------------
'★ ﾕｰｻﾞｰ設定 (1) ：処理ﾃﾞｰﾀの拡張子 (小文字で指定)
'--------------------------------------------------
Public Const SourceFileExtention = "txt"

'--------------------------------------------------
'★ ﾕｰｻﾞｰ設定 (2) ：設定ﾃﾞｰﾀの拡張子 (小文字で指定)
'--------------------------------------------------
Public Const AppendFileExtention = "dat"

'---------------------------------------------------------------
Public Const AD_QUIET = 0  ' ﾒｯｾｰｼﾞを出さない
Public Const AD_ERROR = 1  ' ｴﾗｰのみ表示
Public Const AD_INFO = 3  ' すべての処理を表示

Public LogLevel

'--------------------------------------------------
'★ ﾕｰｻﾞｰ設定 (3) ：実行時のﾒｯｾｰｼﾞ出力ﾚﾍﾞﾙ
'--------------------------------------------------
LogLevel = AD_INFO

Public LogText
LogText = ""

'---------------------------------------------------------------
Public fso
Set fso = CreateObject("Scripting.FileSystemObject")

'---------------------------------------------------------------
' 処理開始
'---------------------------------------------------------------
 Call Main()
 If LogLevel <> AD_QUIET And Len( LogText ) > 0 Then WScript.Echo LogText
 WScript.Quit

'---------------------------------------------------------------
Sub Main()
'---------------------------------------------------------------
 Dim sourceFilePath
 sourceFilePath = ""

 Dim dataFilePath
 dataFilePath = ""

  '// 引数処理
 Dim i
 With WScript.Arguments
 For i=0 To WScript.Arguments.Count - 1
 If fso.FileExists( .Item(i) ) = False Then
 writeLog AD_ERROR, .Item(i) & "がありません｡"
 Exit Sub
 Else
 Select Case LCase( fso.GetExtensionName( .Item(i) ) )
 Case SourceFileExtention
 If sourceFilePath <> "" Then
 writeLog AD_ERROR, "変更ﾌｧｲﾙは複数指定できません｡"
 Exit Sub
 Else
 sourceFilePath = .Item(i)
 End If
 Case AppendFileExtention
 If dataFilePath <> "" Then
 writeLog AD_ERROR, "ﾃﾞｰﾀﾌｧｲﾙは複数指定できません｡"
 Exit Sub
 Else
 dataFilePath = .Item(i)
 End If
 Case Else
 writeLog AD_ERROR, "処理できない拡張子です｡"
 Exit Sub
 End Select
 End If
 Next
 End With

 If sourceFilePath = "" Or dataFilePath = "" Then
 writeLog AD_ERROR, "変更ﾌｧｲﾙ(*." & SourceFileExtention & ") と ﾃﾞｰﾀﾌｧｲﾙ(*." & AppendFileExtention & ")を指定してください｡"
 Exit Sub
 End If

'// ﾌｧｲﾙ処理
 Dim sourceLines
 sourceLines = Split( fso.OpenTextFile( sourceFilePath ).ReadAll(), vbNewLine )

 Dim dataLines
 dataLines = Split( fso.OpenTextFile( dataFilePath ).ReadAll(), vbNewLine )

 Dim dataLine
 Dim dataNum
 dataNum = 0
 For Each dataLine In dataLines
 If InStr( dataLine, "<=" ) > 0 Then
 dataNum = AppendData( sourceLines, dataLine, dataNum )
 End If
 If dataNum < 0 Then Exit Sub
 Next

 Dim nowDateTime
 nowDateTime = FormatDateTime( Now(), 0 )
 nowDateTime = Replace( nowDateTime, "/", "" )
 nowDateTime = Replace( nowDateTime, ":", "" )
 nowDateTime = Replace( nowDateTime, " ", "_" )
 With fso.CreateTextFile( Left( sourceFilePath, Len(sourceFilePath) - 4 ) & "_" & nowDateTime & "." & sourceFileExtention )
 .Write Join( sourceLines, vbNewLine )
 End With

End Sub

'---------------------------------------------------------------
Function AppendData( sourceLines, dataLine, dataNum )
'---------------------------------------------------------------
 Dim apDataSet
 apDataSet = Split( dataLine, "<=" )

 Dim sectionName
 Dim sectionData
 sectionName = Trim( apDataSet(0) )
 sectionData = Trim( apDataSet(1) )

 Dim findFlag
'// ｾｸｼｮﾝ検索
 findFlag = False

 Dim i
 Dim dstLine
 For i=LBound( sourceLines ) To UBound( sourceLines )
 If InStr( Trim( sourceLines(i) ) ,sectionName ) = 1 Then
 dstLine = i
 findFlag = True
 Exit For
 End If
 Next
 If findFlag = False Then
 writeLog AD_ERROR, "ｾｸｼｮﾝ " & sectionName & " がありませんでした｡"
 AppendData = -1
 Exit Function
 End If

 Dim j
 Dim num
 Dim tmpLine
 If dataNum = 0 Then
'// 主ﾃﾞｰﾀ処理
 For j = i + 1 To UBound( sourceLines )
  '// 空ﾃﾞｰﾀﾗｲﾝ検索
  '// ｾｸｼｮﾝ内の空き DATA=
 If InStr( sourceLines(j), "DATA" ) > 0 Then dstLine = j

 If Right( Trim( sourceLines(j) ), 1 ) = "=" Then
 writeLog AD_INFO, "ｾｸｼｮﾝ " & sectionName & " に " & sourceLines(j) & " " & sectionData & "を設定します｡"
 sourceLines(j) = Trim( sourceLines(j) ) & " " & sectionData
 AppendData = getDataNumber( sourceLines(j) )
 Exit Function
 End If

 If InStr( sourceLines(j), "<" ) = 1 Then Exit For
 Next

 If InStr( sourceLines( dstLine ), "DATA" ) > 0 Then
  '// ｾｸｼｮﾝ内に空き DATAnn = が無い
 num = getDataNumber( sourceLines(dstLine) ) + 1
 Else
  '// ｾｸｼｮﾝ内に DATAnn = が無い
 num = 1
 End If
 writeLog AD_INFO, "ｾｸｼｮﾝ " & sectionName & " に DATA" & num & " = " & sectionData & " を追加します｡"
 sourceLines(dstLine) = sourceLines(dstLine) & vbNewLine & "DATA" & num & " = " & sectionData
 sourceLines = Split( Join( sourceLines, vbNewLine ), vbNewLine )
 AppendData = num
 Else
'// 従ﾃﾞｰﾀ処理
  '// 空ﾃﾞｰﾀﾗｲﾝ検索
 For j = i + 1 To UBound( sourceLines )
  '// ｾｸｼｮﾝ内の空き DATA=
 If InStr( sourceLines(j), "DATA" ) > 0 Then
 If getDataNumber( sourceLines(j) ) = dataNum Then
 tmpLine = Trim( sourceLines(j) )
 If Right( tmpLine, 1 ) = "=" Then
 writeLog AD_INFO, "ｾｸｼｮﾝ " & sectionName & " に DATA" & dataNum & " = " & sectionData & " を追加します｡"
 sourceLines(j) = tmpLine & " " & sectionData
 Else
 writeLog AD_ERROR, "ｾｸｼｮﾝ " & sectionName & " の DATA" & dataNum & " は既に設定されています｡"
 AppendData = -1
 End If
 Exit Function
 End If
 dstLine = j
 End If
 If InStr( sourceLines(j), "<" ) = 1 Then Exit For
 Next

 Dim stNum
 If InStr( sourceLines( dstLine ), "DATA" ) > 0 Then
 stNum = getDataNumber( sourceLines(dstLine) ) + 1
 Else
 stNum = 1
 End If

 For j = stNum To dataNum - 1
 writeLog AD_INFO, "ｾｸｼｮﾝ " & sectionName & " に DATA" & num & " を追加します｡"
 sourceLines(dstLine) = sourceLines(dstLine) & vbNewLine & "DATA" & j & " ="
 Next
 writeLog AD_INFO, "ｾｸｼｮﾝ " & sectionName & " に DATA" & dataNum & " = " & sectionData & " を追加します｡"
 sourceLines(dstLine) = sourceLines(dstLine) & vbNewLine & "DATA" & dataNum & " = " & sectionData
 sourceLines = Split( Join( sourceLines, vbNewLine ), vbNewLine )
 AppendData = dataNum
 End If
End Function

'---------------------------------------------------------------
Function getDataNumber( strData )
'---------------------------------------------------------------
 Dim retNum

 If InStr( strData, "=" ) Then
 retNum = Split( strData, "=" )(0)
 Else
 retNum = strData
 End If

 retNum = Trim( Replace( retNum, "DATA", "" ) )
 If IsNumeric( retNum ) Then
 getDataNumber = CLng( retNum )
 Else
 getDataNumber = -1
 End If
End Function

'---------------------------------------------------------------
Sub writeLog( msgLevel, msg )
'---------------------------------------------------------------
 Select Case LogLevel
 Case AD_INFO
 If msgLevel = AD_ERROR Then
 LogText = LogText & "[ERROR !!] " & msg & vbNewLine
 Else
 LogText = LogText & msg & vbNewLine
 End If
 Case AD_ERROR
 If msgLevel = AD_ERROR Then
 LogText = LogText & "[ERROR !!] " & msg & vbNewLine
 End If
 End Select
End Sub
Mookさんのｺﾒﾝﾄ
ｺｰﾄﾞを少し整理し､出力の機能をﾚﾍﾞﾙ設定できるようにしました｡
gocnia3さんのｺﾒﾝﾄ
すみません｡回答遅くなりました 想定通りの動きです ﾍﾞｽﾄｱﾝｻｰをありがとうございます 少し中身の動きを確認してます(いまやっとｾｸｼｮﾝの空白処理の確認が終わったとこです) 終わったあとに少し確認させて下さい(^ ^)
gocnia3さんのｺﾒﾝﾄ
すみません｡ ﾎﾟｲﾝﾄを2倍にさせていただきますので､以下仕様に変更頂けませんか ?･特定の一つのｾｸｼｮﾝに今までの仕様通りに設定を追加してその追加方法を ? ?記憶し､その他のｾｸｼｮﾝについても同様の方法で追加します｡ ? ?例としては以下となります｡ ■特定のｾｸｼｮﾝ ･ｾｸｼｮﾝ<2TEST2> ■追加したい設定項目 ･ｾｸｼｮﾝ<2TEST2>の行下にある設定項目の空きに｢HHH9｣を追加する｡←★ここは一緒 ･ｾｸｼｮﾝ<1TEST1>の行下にある設定項目にｾｸｼｮﾝ<2TEST2>でいれた箇所と同じ場所に｢GGG9｣を追加する｡ ←★ここが変更点 ･ｾｸｼｮﾝ<3TEST3>の行下にある設定項目にｾｸｼｮﾝ<2TEST2>をいれた箇所と同じ場所に｢FFF9｣を追加する｡ ←★ここが変更点 ★★★★★★★例?★★★★★★★ ■ﾃｷｽﾄﾌｧｲﾙの中身(ｿｰｽﾌｧｲﾙ) -----ここから----- <1TEST1> 'ｾｸｼｮﾝ1 DATA1 = GGG1 DATA2 = GGG2 DATA3 =? DATA4 = DATA5 = <2TEST2> 'ｾｸｼｮﾝ1 DATA1 = HHH1 DATA2 = HHH2 DATA3 = HHH3 DATA4 = DATA5 = <3TEST3> 'ｾｸｼｮﾝ1 DATA1 = FFF1 DATA2 =? DATA3 =? DATA4 = DATA5 = -----ここまで----- ■実行後のﾃｷｽﾄﾌｧｲﾙの中身 -----ここから----- <1TEST1> 'ｾｸｼｮﾝ1 DATA1 = GGG1 DATA2 = GGG2 DATA3 =? DATA4 = GGG9 DATA5 = <2TEST2> 'ｾｸｼｮﾝ1 DATA1 = HHH1 DATA2 = HHH2 DATA3 = HHH3 DATA4 = HHH9 DATA5 = <3TEST3> 'ｾｸｼｮﾝ1 DATA1 = FFF1 DATA2 =? DATA3 =? DATA4 = FFF9 DATA5 = -----ここまで----- ★★★★★★★例?★★★★★★★ ■ﾃｷｽﾄﾌｧｲﾙの中身(ｿｰｽﾌｧｲﾙ) -----ここから----- <1TEST1> 'ｾｸｼｮﾝ1 DATA1 = GGG1 DATA2 = GGG2 DATA3 = GGG3 DATA4 = DATA5 = <2TEST2> 'ｾｸｼｮﾝ1 DATA1 = HHH1 DATA2 = HHH2 DATA3 = HHH3 DATA4 = HHH4 DATA5 = HHH5 <3TEST3> 'ｾｸｼｮﾝ1 DATA1 = FFF1 DATA2 = FFF2 DATA3 = FFF3 DATA4 = DATA5 = -----ここまで----- ■実行後のﾃｷｽﾄﾌｧｲﾙの中身 -----ここから----- <1TEST1> 'ｾｸｼｮﾝ1 DATA1 = GGG1 DATA2 = GGG2 DATA3 = GGG3 DATA4 = DATA5 = DATA6 = GGG9 <2TEST2> 'ｾｸｼｮﾝ1 DATA1 = HHH1 DATA2 = HHH2 DATA3 = HHH3 DATA4 = HHH4 DATA5 = HHH5 DATA6 = HHH9 <3TEST3> 'ｾｸｼｮﾝ1 DATA1 = FFF1 DATA2 = FFF2 DATA3 = FFF3 DATA4 = DATA5 = DATA6 = FFF9
Mookさんのｺﾒﾝﾄ
確認ですけれども､一度に追加するﾃﾞｰﾀは 各ｾｸｼｮﾝ(<#TEST#> をｾｸｼｮﾝと呼んでいますが正しいですか？) に対して同時に設定するﾜﾝｾｯﾄだけとなりますか？ つまり､同じｾｸｼｮﾝに対して複数を同時に登録することが無いか？ ということになります｡ ある場合､どれがｾｯﾄ(DATA# を同じところにするか)の紐付けの 仕組みが必要となりますが､それは必要ですか？ つまり､追加ﾃﾞｰﾀとして､ ?????????????????????? <1TEST1> <= GGG-1 <2TEST2> <= HHH-1 <2TEST2> <= HHH-2 <3TEST3> <= FFF-1 <3TEST3> <= FFF-2 <3TEST3> <= FFF-3 ?????????????????????? のようなｹｰｽが無いか､ということです｡ 仕様確認できましたら､夜にでも対応します｡
Mookさんのｺﾒﾝﾄ
2TEST2 と指定していますが､ 結局DATA の番号は3つのｾｸｼｮﾝの中で､3箇所とも空きのある 最小の番号となると思いますが､その認識でよいですか？
gocnia3さんのｺﾒﾝﾄ
＞確認ですけれども､一度に追加するﾃﾞｰﾀは ＞各ｾｸｼｮﾝ(<#TEST#> をｾｸｼｮﾝと呼んでいますが正しいですか？) ＞に対して同時に設定するﾜﾝｾｯﾄだけとなりますか？ その認識であってます｡ 同じｾｸｼｮﾝに対して複数を同時に登録することはありません｡ ＞2TEST2 と指定していますが､ ＞結局DATA の番号は3つのｾｸｼｮﾝの中で､3箇所とも空きのある ＞最小の番号となると思いますが､その認識でよいですか？ ちょっと違います｡ 例1として <2TEST2>で空きの合る｢DATA4 =｣に設定をした場合 その他のｾｯｼｮﾝでも｢DATA4 =｣に設定します｡ その他のｾｯｼｮﾝへの追加の際に空きがあるかは関係なしに追加していただいて問題ないです｡ (ｷｰｾｸｼｮﾝに値が入っていればその他ｾｸｼｮﾝにも値も入っていない仕様のため) 例2として <2TEST2>で空きがないために｢DATA6 =｣を追加して設定をした場合 その他のｾｯｼｮﾝでも｢DATA6 =｣を追加して設定します｡ その他のｾｯｼｮﾝにまだ入力されてない空きがあっても｢DATA6 =｣を作成して入れます｡
Mookさんのｺﾒﾝﾄ
確認です｡ 2TEST2 を基準にするという指定があった場合､ 2TEST2 で DATA4 が設定場所であった場合､他のｾｸｼｮﾝは (1)DATA4 が既に有っても(無いという想定ですが)､置き換えてよいですか？ それともｴﾗｰ終了したほうが良いですか？ (2)DATA1 までしかなかった場合､DATA2､DATA3 はｽｷｯﾌﾟして DATA1 = 既存設定項目 DATA4 = 設定項目 としますか､それとも補完して DATA1 = 既存設定項目 DATA2 = DATA3 = DATA4 = 設定項目 のようにしますか？ (3)再度の確認ですが､一度の登録ではﾃﾞｰﾀはﾜﾝｾｯﾄのみで 複数あっても 2つ以降は無視する(あるいはｴﾗｰ終了する) という仕様でもよいですか？
gocnia3さんのｺﾒﾝﾄ
＞(1)DATA4 が既に有っても(無いという想定ですが)､置き換えてよいですか？ ＞ それともｴﾗｰ終了したほうが良いですか？ ｴﾗｰ終了でお願いします｡ ＞(2)DATA1 までしかなかった場合､DATA2､DATA3 はｽｷｯﾌﾟして… 補完をお願いします｡ ＞(3)再度の確認ですが､一度の登録ではﾃﾞｰﾀはﾜﾝｾｯﾄのみで… ｴﾗｰ終了で問題ありません｡
gocnia3さんのｺﾒﾝﾄ
すみません｡ 作成途中でも構わないので､頂けないでしょうか 宜しくお願いします｡
Mookさんのｺﾒﾝﾄ
複数ﾃﾞｰﾀの判定部分は未対応ですが､ お急ぎのようでしたので更新します｡ 先頭ｾｸｼｮﾝの位置を全体に反映します｡
Mookさんのｺﾒﾝﾄ
考えてみたら､ 同じｾｸｼｮﾝが複数あったら､結果的にｴﾗｰになるので､ 判定処理は不要のようです｡ 挙動に問題がなければ､これが最終版となります｡
gocnia3さんのｺﾒﾝﾄ
ありがとうございます｡ 以前作っていただいたものを改変して自分で作ってみました｡ しかしやっぱり整理されているものは違いますね笑 正直ｿｰｽを読んで､調べながら理解できても､作っていただいたようなものを自分で作成できる気がしません笑(特に配列の処理の仕方など)｡やはり勉強あるのみなんですかね ここまで作っていただきありがとうございました｡ じっくり時間をかけて読ませていただきます｡ ありがとうございました｡
Mookさんのｺﾒﾝﾄ
要望されていたことはできたでしょうか｡ 多くのﾎﾟｲﾝﾄありがとうございました｡ 中身を見ようと思っていただけて､こちらも嬉しく思います｡
関連質問
●質問をもっと探す●

0.人力検索はてなﾄｯﾌﾟ
8.このﾍﾟｰｼﾞを友達に紹介
9.このﾍﾟｰｼﾞの先頭へ
□対応機種一覧
□お問い合わせ
□ﾍﾙﾌﾟ/お知らせ
□ﾛｸﾞｲﾝ
□無料ﾕｰｻﾞｰ登録
□はてなﾄｯﾌﾟ