ｴｸｾﾙで入力したﾃﾞｰﾀを指定の形でcsvﾌｧｲﾙとして吐き出したい｡添付画像?のように列Cは｢ｻｲｽﾞ｣列Dは｢状態｣などの項目を作りそれぞれの行にﾃﾞｰﾀを入力し…

ｴｸｾﾙで入力したﾃﾞｰﾀを指定の形でcsvﾌｧｲﾙとして吐き出したい｡

添付画像?のように
列Cは｢ｻｲｽﾞ｣列Dは｢状態｣
などの項目を作りそれぞれの行にﾃﾞｰﾀを入力します｡

そして画像?のようなﾃﾝﾌﾟﾚ.txtを作ります｡

そして何らかの方法で､多分ｴｸｾﾙ､ﾏｸﾛ？で何とかすれば
?のようなCSVﾌｧｲﾙを吐き出せるのでは無いかと思っています｡
可能でしょうか？
もしｴｸｾﾙで､できるのであればどうやればよいでしょうか｡

また
?で入力した列Eの｢販売価格｣は?のCSVでは列Cに何も加工を加えずに
吐き出すようにしたいです｡

今回質問させていただくためにｼﾝﾌﾟﾙになﾃﾞｰﾀを作りましたが
項目はもっとたくさんあります｡

今使用しているｴｸｾﾙのﾊﾞｰｼﾞｮﾝは2003です｡
以上どうかよろしくお願いします｡

ﾃﾝﾌﾟﾚｰﾄﾌｧｲﾙを使用して CSV ﾃﾞｰﾀを作成するｽｸﾘﾌﾟﾄを作成してみました｡

事前に以下のﾊﾟｽを修正の上､実行願います｡

' Excelﾃﾞｰﾀﾌｧｲﾙﾌｧｲﾙを指定します
Const g_strExcelFile = "C:\home\edu\hatena\orekojinn\1368499599\book1.xls"
' ﾃﾝﾌﾟﾚｰﾄﾌｧｲﾙを指定します
Const g_strTemplateFile = "C:\home\edu\hatena\orekojinn\1368499599\template.txt"
' 出力先のCSVﾌｧｲﾙ名を指定します
Const g_strCsvFile = "C:\home\edu\hatena\orekojinn\1368499599\out.csv"

なお､Excel VBA ではなく､VBScript でのｻﾝﾌﾟﾙとなっております｡
(少し修正すれば､VBA で動作させることも可能です｡必要であれば修正します｡)

実行するには､ｴｸｽﾌﾟﾛｰﾗより｢ExcelToCsv.vbs｣をﾀﾞﾌﾞﾙｸﾘｯｸするか､ｺﾏﾝﾄﾞﾗｲﾝ(cmd.exe)より､｢CScript ExcelToCsv.vbs [Enter]｣を行ってください｡
実行すると出力先の CSV ﾌｧｲﾙが作成されます｡

' File : ExcelToCsv.vbs
' Usage : CScript //Nologo ExcelToCsv.vbs
Option Explicit

' Excelﾃﾞｰﾀﾌｧｲﾙﾌｧｲﾙを指定します
Const g_strExcelFile = "C:\home\edu\hatena\orekojinn\1368499599\book1.xls"
' ﾃﾝﾌﾟﾚｰﾄﾌｧｲﾙを指定します
Const g_strTemplateFile = "C:\home\edu\hatena\orekojinn\1368499599\template.txt"
' 出力先のCSVﾌｧｲﾙ名を指定します
Const g_strCsvFile = "C:\home\edu\hatena\orekojinn\1368499599\out.csv"

Call Main()

Sub Main()
 Dim strTemplate
  ' ﾃﾝﾌﾟﾚｰﾄﾌｧｲﾙのﾃｷｽﾄの内容を変数に読み込む
 strTemplate = GetTextFromFile( g_strTemplateFile )
 
  ' Excel ﾌｧｲﾙの内容をﾃﾝﾌﾟﾚｰﾄの内容に基づき CSV 出力する
 Call ConvertExcelToCsvFile( g_strExcelFile, strTemplate, g_strCsvFile )
End Sub

' Excel ﾌｧｲﾙの内容をﾃﾝﾌﾟﾚｰﾄの内容に基づき CSV 出力する
Sub ConvertExcelToCsvFile( strFileName, strTemplate, g_strCsvFile )
 Dim cn
 Set cn = CreateObject("ADODB.Connection")
 
  ' Excel 97-2003 であれば､以下を有効化します｡
 cn.Open "PROVIDER=Microsoft.Jet.OLEDB.4.0;Data Source=" & strFileName & ";Extended Properties=""Excel 8.0;HDR=Yes;"""
  ' Excel 2007/2010 の場合は､以下を有効化します｡
  'cn.Open "PROVIDER=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFileName & ";Extended Properties=""Excel 12.0;HDR=Yes;"""
 
 Dim rs
  ' Excel のｼｰﾄ名が｢Sheet1｣でない場合､下記の名称を変更してください｡
 Set rs = cn.Execute("SELECT * FROM [Sheet1$]")
 
 Dim strLine
 Dim strBaseName
 
 Dim strDelimiter
 strDelimiter = "," ' 出力ﾌｧｲﾙの区切り文字として｢,｣を使用します｡
 
 Dim strNo  ' 管理番号
 Dim strTitle ' ﾀｲﾄﾙ
 Dim strSize  ' ｻｲｽﾞ
 Dim strState ' 状態
 Dim nPrice  ' 販売金額
 
 Dim strItemInfo ' 商品説明
 strItemInfo = strTemplate

 strLine = Join( Array("管理番号","商品説明文","販売価格"), strDelimiter )
  ' 項目行をﾌｧｲﾙ出力
 Call WriteLineToFile( strLine, g_strCsvFile )
 
  ' ﾚｺｰﾄﾞ件数分､順次取得します
 While Not rs.BOF And Not rs.EOF
  ' 各項目の値を取得
 strNo = rs("管理番号")
 strTitle = rs("ﾀｲﾄﾙ")
 strSize = rs("ｻｲｽﾞ")
 strState = rs("状態")
 nPrice = rs("販売価格")
 
  ' ﾃﾝﾌﾟﾚｰﾄの内容に基づき置換
 strItemInfo = Replace( strItemInfo, "＜ﾀｲﾄﾙ＞", strTitle ) ' ＜ﾀｲﾄﾙ＞ を置換
 strItemInfo = Replace( strItemInfo, "＜ｻｲｽﾞ＞", strSize ) ' ＜ｻｲｽﾞ＞ を置換
 strItemInfo = Replace( strItemInfo, "＜状態＞", strState ) ' ＜状態＞ を置換
 
  ' ｢管理番号,商品説明文,販売価格｣の CSV ﾃﾞｰﾀを作成する
 strLine = _
 Chr(34) & strNo & Chr(34) & strDelimiter & _
 Chr(34) & strItemInfo & Chr(34) & strDelimiter & _
 CStr( nPrice )
 
  ' CSV ﾃﾞｰﾀをﾌｧｲﾙ出力
 Call WriteLineToFile( strLine, g_strCsvFile )
  ' 次のﾚｺｰﾄﾞに移動
 rs.MoveNext
 Wend

End Sub

' ﾃﾞｰﾀをﾌｧｲﾙ出力する
Function WriteLineToFile( strLine, strFileName )
 Dim fso
 Set fso = CreateObject("Scripting.FileSystemObject")
 
 Dim file
 Set file = fso.OpenTextFile(strFileName, 8, True) ' 追加書き込みﾓｰﾄﾞ
 
 file.WriteLine strLine
 file.Close
End Function

' ﾃｷｽﾄﾌｧｲﾙを読み込む
Function GetTextFromFile( strFileName )
 Dim strResult
 
 Dim fso
 Set fso = CreateObject("Scripting.FileSystemObject")

 Dim file
 Set file = fso.OpenTextFile(strFileName, 1) ' ForReading = 1
 
 strResult = file.ReadAll
 
 GetTextFromFile = strResult
End Function