>WEB上にはSYMBOLが22個並んでおり､有る条件を満たすとPROBABILITYのﾃﾞｰﾀｰが出てきます｡
>なお､ﾃﾞｰﾀｰはいろいろなｼﾝﾎﾞﾙについて同時に出たり出なかったり様々です｡

画面上にはtableがあり，この表の1列目｢SYMBOL｣の値が｢USDJPY｣であるような行がある｡
その行の3列目には，いつもPROBABILITYのﾃﾞｰﾀが表示されているとは限らないが，
PROBABILITYのﾃﾞｰﾀが表示されているﾀｲﾐﾝｸﾞもある｡
もしUSDJPYのPROBABILITYの値が表示されていれば，その値を取得したい｡

という事でよろしいですね｡


下記のｺｰﾄﾞをどうぞ｡

// ｱｸｾｽしたいﾍﾟｰｼﾞのURL
url = "http://name-of-this-site.org/coding/dummy/1387280635q/"


// 新規IEｵﾌﾞｼﾞｪｸﾄを作成
ie = createOLEobj("InternetExplorer.Application")

// 起動中のIEを見えるように
ie.visible = True
wid = hndtoid( ie.hwnd )
acw( wid )


// 対象ﾍﾟｰｼﾞを開く
ie.navigate( url )
ie_wait( ie )





// まずﾃｰﾌﾞﾙを取得
tables = ie.document.getElementsByTagName("table")
found_table = false
target_table = empty
// http://canal22.org/control/buitinconstant/
for i = 0 to tables.length - 1
ifb tables.item( i ).className = "alert-table" then
// http://d.hatena.ne.jp/vividcode/20100327/1269724469

// [i]で参照しようとすると｢次元数が合いません｣のｴﾗｰになる
// http://canal22.org/advance/ie/parent-child-ta/

//msgbox( "ﾃｰﾌﾞﾙを発見" )
found_table = true
target_table = tables.item( i )
endif
next
ifb found_table <> true then
// http://mission-o.seesaa.net/article/121325919.html

msgbox( "ﾃｰﾌﾞﾙを発見できませんでした｡" )

// 終了
exitexit
endif


// ﾃｰﾌﾞﾙからﾃﾞｰﾀを取得
trs = target_table.getElementsByTagName("tr")
for j = 1 to trs.length - 1 // 先頭行はｽｷｯﾌﾟして1から
tds = trs.item( j ).getElementsByTagName("td")

// SYMBOLを確認
ifb tds.item(0).innerText = "USDJPY" then
// 該当行を発見

str = tds.item(2).innerText
ifb pos( "%", str ) > 0 then
// ｾﾙの中に｢%｣という文字があれば，ﾃﾞｰﾀが表示されていると考える｡
// http://uwsc.dohow.jp/blog/pos.html

str_arr = split( str, " " ) 
// 半角ｽﾍﾟｰｽで分割する
// http://canal22.org/kansu/split/

data1 = str_arr[0]
data2 = str_arr[1]
msgbox("ﾃﾞｰﾀは" + data1 + "および" + data2 + "です｡" )
// ﾃﾞｰﾀ取得完了｡取得したﾃﾞｰﾀをもとに好きな処理をすればよい｡
else
msgbox("USDJPYの行にはﾃﾞｰﾀがありませんでした｡")
// このﾒｯｾｰｼﾞを表示せずに，待機し続けてもよい｡
endif

endif

next



// IEがﾋﾞｼﾞｰ状態の間待ちます
procedure ie_wait( ie )
 repeat
 sleep( 0.1 )
 until ( ! ie.busy ) and ( ie.readystate = 4 )
 sleep( 0.1 )
fend


// ｺｰﾄﾞ全体の参考：
// http://d.hatena.ne.jp/language_and_engineering/20090729/p1

このｺｰﾄﾞは実際に動作します｡

この質問に回答するために，動作ﾃｽﾄ用のﾍﾟｰｼﾞとして下記のURLを設置しました｡
http://name-of-this-site.org/coding/dummy/1387280635q/

上のｺｰﾄﾞでは，ここにｱｸｾｽしてﾃﾞｰﾀを取っています｡

実際の利用時には，ご自分がｱｸｾｽするURLに変更して下さい｡

また，ﾃﾞｰﾀが表示されていない時には待機してから再度処理を試みる，
等の場合には，このｺｰﾄﾞの｢ﾃｰﾌﾞﾙを取得｣以降の部分を定期的にﾙｰﾌﾟで回す事になります｡