VBSの質問です hogeﾌｫﾙﾀﾞにvbsが置かれています hogeﾌｫﾙﾀﾞ内のｻﾌﾞﾌｫﾙﾀﾞ内のa.htmlを探し hogeﾌｫﾙﾀﾞ内の全htmlﾌｧｲﾙを取得し一つ上のﾌｫﾙﾀﾞのﾃｷｽﾄﾌ…

VBSの質問です
hogeﾌｫﾙﾀﾞにvbsが置かれています
hogeﾌｫﾙﾀﾞ内のｻﾌﾞﾌｫﾙﾀﾞ内のa.htmlを探し
hogeﾌｫﾙﾀﾞ内の全htmlﾌｧｲﾙを取得し
一つ上のﾌｫﾙﾀﾞのﾃｷｽﾄﾌｧｲﾙに入力したいと思うのですがうまく動きません
どうすれば動くでしょうか？よろしくお願いします

targetFolderName = "."

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)
Set parentFolder = targetFolder.ParentFolder
Set output = fs.CreateTextFile(parentFolder.Path & "\list.html", True)
For Each folder In targetFolder.SubFolders
 For Each f In folder.Files
 If f.Name = "kekka.html" Then
 output.WriteLine "http://" & targetFolder.Name & "/" & folder.Name & "/"
 End If
 Next
Next
targetFolderName = "../"
For Each folder In targetFolder.files
 For Each f In folder.Files
 If f.Name = "*.html" Then
 output.WriteLine "http://" & targetFolder.Name & "/" & folder.Name & "/"
 End If
 Next
Next
output.Close

以下の二つの質問のｽｸﾘﾌﾟﾄを､ひとつにまとめます｡
http://q.hatena.ne.jp/1417475886
http://q.hatena.ne.jp/1417531694

こんな感じになります｡

targetFolderName = "D:\test\hoge"  ' ※ hoge ﾌｫﾙﾀﾞのﾊﾟｽ

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)

Set parentFolder = targetFolder.ParentFolder
Set output = fs.CreateTextFile(parentFolder.Path & "\list.html", True)
output.WriteLine "ｱﾄﾞﾚｽ一覧"

' hoge ﾌｫﾙﾀﾞのｻﾌﾞﾌｫﾙﾀﾞにある a.html を探す
For Each folder In targetFolder.SubFolders
 For Each f In folder.Files
 If f.Name = "a.html" Then
 output.WriteLine "http://" & targetFolder.Name & "/" & folder.Name & "/" & f.Name
 End If
 Next
Next

' hoge ﾌｫﾙﾀﾞにある .html ﾌｧｲﾙを探す
For Each f In targetFolder.Files
 If fs.GetExtensionName(f.Path) = "html" Then
 output.WriteLine "http://" & targetFolder.Name & "/" & f.Name
 End If
Next

output.WriteLine "以上"
output.Close