VBSの質問です
hoge ﾌｫﾙﾀﾞの中に
a.html
b.html
c.html
d.html
･
･
･

というようにﾃｷｽﾄﾌｧｲﾙがたくさん入っています

hogeの一つ上のﾌｫﾙﾀﾞに以下のﾃｷｽﾄが入力されたhtmlﾌｧｲﾙを作りたいのですがどのようなVBSを組めばいいでしょうか？教えてください

hoge.html
＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
<tr><td>http://hoge/a.html</td><td>http://hoge/b.html</td></tr>
<tr><td>http://hoge/c.html</td><td>http://hoge/d.html</td></tr>
<tr><td>http://hoge/･.html</td><td>http://hoge/･.html</td></tr>
･
･
･
＊＊＊＊＊＊＊＊＊＊＊

こんな感じになります｡

targetFolderName = "D:\test\hoge"  ' ※ hoge ﾌｫﾙﾀﾞのﾊﾟｽ

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)

Set parentFolder = targetFolder.ParentFolder
Set output = fs.CreateTextFile(parentFolder.Path & "\list.html", True)
output.WriteLine "<table>"

For Each f In targetFolder.Files
 If fs.GetExtensionName(f.Path) = "html" Then
 output.WriteLine "<tr><td>http://" & targetFolder.Name & "/" & f.Name & "</td></tr>"
 End If
Next

output.WriteLine "</table>"
output.Close

他で質問されていることも考慮して､以下の処理もしています｡

• hoge ﾌｫﾙﾀﾞの下にある .html ﾌｧｲﾙだけを対象にしています
• 外側を <table> ? </table> でくくっています

---

追記です｡

左端 真ん中 右端で使っているﾀｸﾞは違います

失礼しました｡2列の TABLE なんですね｡
では､こんな感じでは､いかがでしょうか｡

targetFolderName = "D:\test\hoge"  ' ※ hoge ﾌｫﾙﾀﾞのﾊﾟｽ

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)

Set parentFolder = targetFolder.ParentFolder
Set output = fs.CreateTextFile(parentFolder.Path & "\list.html", True)
output.WriteLine "<table>"

odd = True
For Each f In targetFolder.Files
 If fs.GetExtensionName(f.Path) = "html" Then
 If odd Then
 output.Write "<tr><td>http://" & targetFolder.Name & "/" & f.Name & "</td>"
 odd = False
 Else
 output.WriteLine "<td>http://" & targetFolder.Name & "/" & f.Name & "</td></tr>"
 odd = True
 End If
 End If
Next

output.WriteLine "</table>"
output.Close

(C)株式会社はてな