ｴｸｾﾙVBA､文字列の中に､数字(半角､全角とも)が含まれていない場合､色をつけたい｡ A､I､E列の､2行､6行､10行､14行･･･(102行まで4行飛び) に住所の文字列が…

ｴｸｾﾙVBA､文字列の中に､数字(半角､全角とも)が含まれていない場合､色をつけたい｡

A､I､E列の､2行､6行､10行､14行･･･(102行まで4行飛び)

に住所の文字列が入っています｡

そのときに､半角､全角問わず､1234567890､1234567890の数字が入って【いない】ときだけ､ﾌｫﾝﾄを赤く､太字で表示させたいのです｡

条件付き書式をやってみましたが､どうもうまくいきませんでした｡
(countif利用の相対参照等で)

ですので､ﾏｸﾛ回答を期待いたします｡

よろしくお願いいたします｡

>半角､全角問わず､
>1234567890､
>1234567890
>の数字が入って【いない】ときだけ､
>ﾌｫﾝﾄを赤く､
>太字で表示させたいのです｡

下記､ﾃｽﾄ動画です｡
https://www.youtube.com/watch?v=aqiy53cyVGs

北海道
北海道札幌市1-2-3
神奈川県横浜市99番地
神奈川県町田市五丁目六番七号
沖縄XXXｱﾊﾟｰﾄ201号

1.下記のﾓｼﾞｭｰﾙを貼り付ける
※alt+F11や開発から

Option Explicit

'半角の0から9
'全角の0から9
'が､一文字でも入っていたら"OK"の文字を返す
'入っていないときは"NG"を返す そんなﾕｰｻﾞ関数を作成

Public Function chk0_9(strCHK As String) As String

 Dim strRET As String  'ﾘﾀｰﾝ値
 
 Dim n As Integer
 
 Dim strMOJI As String  '一文字
 Dim nCODE As Integer '文字ｺｰﾄﾞを保管
 
 strRET = "NG"  'NG ｴﾗｰで初期化
 
 For n = 1 To Len(strCHK)  '先頭1文字目から文字数分ﾙｰﾌﾟ
 strMOJI = Mid(strCHK, n, 1)  '一文字取り出す
 nCODE = Asc(strMOJI)  '文字ｺｰﾄﾞに変換
 
  '範囲をﾁｪｯｸする
 If Asc("0") <= nCODE And nCODE <= Asc("9") Then
 strRET = "OK"  '一文字でも見つかったのでﾘﾀｰﾝ値にOKｾｯﾄ
 Exit For  'ひとつでも見つかればﾙｰﾌﾟを抜ける
 End If

  '全角数字のﾁｪｯｸ
 If Asc("0") <= nCODE And nCODE <= Asc("9") Then
 strRET = "OK"  '一文字でも見つかったのでﾘﾀｰﾝ値にOKｾｯﾄ
 Exit For  'ひとつでも見つかればﾙｰﾌﾟを抜ける
 End If

 Next
 
 chk0_9 = strRET  '最後にﾘﾀｰﾝ値をｾｯﾄして､関数終了
 
End Function

2.ｾﾙの条件書式に式を貼り付ける

2.1 ｾﾙの強調表示ﾙｰﾙ
で
その他を選択する

2.2 数式を使用して､書式設定するｾﾙを決定
式に =chk0_9(ﾁｪｯｸするｾﾙ)="NG" を入れ
書式をｱｶにする

2.3 条件書式をｺﾋﾟｰする
ﾍﾟﾝｷのﾊｹみたいなｱｲｺﾝ？
から
書式をｺﾋﾟｰする

ﾕｰｻﾞ関数と条件書式でやってみました｡
何かの参考となれば､うれしいです･･･
※ぐだぐたのﾃｽﾄ動画は笑ってゆるしてください･･･

以下を試してみてください｡
Excel2016で確認しています｡


Sub chkNum()
Dim wkSh As Worksheet
Dim wkRange As Range
Dim wkAddRange As Range
Dim wkCell As Range
Dim wkStr
Dim wkI
Dim wkFlg
 
 Set wkSh = ActiveSheet
 
 'ﾁｪｯｸ対象ｾﾙ群を決定
 Set wkRange = wkSh.Range("A2, I2, E2")
 For wkI = 6 To 102 Step 4
 Set wkAddRange = wkSh.Range("A" & wkI & ",I" & wkI & ",E" & wkI)
 Set wkRange = Union(wkRange, wkAddRange)
 Next wkI
 
 'ｾﾙ毎に数字を含むかﾁｪｯｸする
 For Each wkCell In wkRange
 wkStr = StrConv(wkCell, vbNarrow) '半角に統一してからﾁｪｯｸする
 wkFlg = 0
 For wkI = 1 To Len(wkStr)
 If Mid(wkStr, wkI, 1) >= "0" And Mid(wkStr, wkI, 1) <= "9" Then
 wkFlg = 1
 Exit For
 End If
 Next wkI
 
 If wkFlg = 0 Then
 'If wkFlg = 0 And (Trim(wkCell) <> "") Then
 ' ↑ｾﾙがﾇﾙおよびﾌﾞﾗﾝｸのみの場合､処置しない(必要でもないけど)
 '数字を含まない場合､ｾﾙの文字ﾌｫﾝﾄの属性を変更する
 wkCell.Font.Color = RGB(255, 0, 0)
 wkCell.Font.Bold = True
 Else
 '設定を戻す
 wkCell.Font.ColorIndex = xlAutomatic
 wkCell.Font.Bold = False
 End If
 Next
 
End Sub

条件付き書式でうまくいかないとのことですが
どううまくいかないのかわかりませんが
判定処理だけVBAとして､それを条件付き書式に使用すればできませんか？

判定条件は､
半角､全角問わず､1234567890､1234567890の数字が入って【いない】
とのことなので､
｢0?9または､0?9が1文字でも含まれているか｣の結果を否定すればよろしいかと｡

例えば､次のようにすれば､数字が含まれていない時､TRUEが返ります｡

Public Function notExistsDigits(ByVal sValue As String) As Boolean

notExistsDigits = Not sValue Like "*[0-90-9]*"

End Function

ちなみに､上記の例では､長さ0の文字列もTRUEが返ります｡