整数の分割というものに興味があり、自分で色々調べたいのですがプログラムが組めないのでどなたか

Perl で作りました。

Windows だと ActivePerl が使えます。

http://pocketstudio.jp/win/activeperl/

以下の内容をファイルに保存してください。（仮に part.pl とします）

#!perl

use strict;
use warnings;

while(<STDIN>) {
  chomp;
  my $x = int $_;
  for(my $i=1; $i<=$x; $i++) {
    my $result = partition_number($x,$i);
    my $combination_result = combination_result($result);
    $combination_result = term_result($combination_result) if @ARGV;
    print_result($combination_result);
  }
}

sub partition_number {
  my ( $n,$i ) = @_;
  my @result = ();
  if ( $n < $i ) {
  } elsif ( $i == 1 ) {
     push @result,[$n];
  } elsif( $n == $i ) {
     push @result, [(1) x $n];
  } else {
     for(my $j=1; $j<=$n &amp;&amp; $j<=$i; $j++ ) {
	 my @sub = @{partition_number($n-$j,$i-1)};
	 foreach ( @sub ) {
	    push @result , [$j,@{$_}];
	 }
     }
  }
  return \@result;
}

sub combination_result {
   my $result = shift;
   my %uniq = ();
   my @combination_result = ();
   foreach my $set ( @{$result} ) {
      my @combination = sort {$b<=>$a} @{$set};
      my $normalize = join ',',@combination;
      next if $uniq{$normalize}++;
      push @combination_result,\@combination;
   }
   return \@combination_result;
}

sub term_result {
   my $result = shift;
   my @term_result = ();
   TERM: foreach my $set ( @{$result} ) {
	my $max = (sort{ $b <=> $a } @{$set} )[0];
	my %term_count = ();
	$term_count{$_}++ for @{$set};
	my $check_count = 0;
	foreach my $term ( reverse 1..$max ) {
	   my $term_count =  $term_count{$term};
	   next TERM unless $term_count;
	   next TERM unless $check_count <= $term_count;
	   $check_count = $term_count;
	}
	push @term_result,$set;
   }
   return \@term_result;
}

sub print_result {
    my $result = shift;
    foreach my $set (@{$result}) {
	 print join(',',@{$set}),"\n";
    }
}

保存したディレクトリでコマンドプロンプトを開き、

perl part.pl

と実行すると入力待ちになり、入力するごとに１番の回答が、

perl part.pl 2

と後ろに何でもいいので文字列を付け加えると同じく入力するごとに２番の回答が出るようになっています。