ExcelのVBAについて質問します。

こんな感じでどうでしょう。

IE終了が必要でしたらコメントアウトの部分を復活させてください。

Sub google()
    Dim IE As Object
    
    Set IE = CreateObject("InternetExplorer.Application")
    IE.Visible = True
    IE.Navigate ("http://www.google.co.jp/")

    'Busy解除まで待つ
    i = 0
    Do Until IE.busy = False Or i > 1000
        i = i + 1
    Loop

    IE.document.all.q.Value = "EXCEL"
    IE.document.all.btnG.Click

'    IE.Quit                      'IE終了処理
'    Set IE = Null
End Sub

IEであれば、オブジェクトとして操作可能ですので、Shell関数で起動するよりも詳細な操作が可能です。

サンプルを示します。

Googleの検索窓にキーワードを入力する方法は色々あります。

Option Explicit
Option Base 0

Sub test()

    Dim objIE As Object
    
    Set objIE = CreateObject("InternetExplorer.Application")
    
    objIE.Visible = True
    
    objIE.navigate "http://www.google.co.jp"
    
    ' ページロード待ち
    Do While objIE.busy And objIE.readystate < 2
    Loop
    
    ' キーワードを入力
    objIE.document.getelementsbyname("f").Item(0).q.Value = "Excel"
    
    ' 検索ボタンを押す（フォームをsubmit）
    objIE.document.getelementsbyname("f").Item(0).submit
    
    ' ページロード待ち
    Do While objIE.busy And objIE.readystate < 2
    Loop
    
    MsgBox "検索完了"
    
    objIE.Quit
    
    Set objIE = Nothing

End Sub

一番確実なのは、最初からキーワード込みのURLを表示することです。

Option Explicit
Option Base 0

Function GetSearchUrl(ByVal searchKeyword As String) As String

    Dim i As Integer
    Dim searchUrl As String

    searchUrl = "http://www.google.com/search?ie=shift_jis&q="
    searchKeyword = StrConv(searchKeyword, vbFromUnicode)
    For i = 1 To LenB(searchKeyword)
        searchUrl = searchUrl & "%" & Right$("0" & Hex$(AscB(MidB$(searchKeyword, i, 1))), 2)
    Next i

    GetSearchUrl = searchUrl
    
End Function

Sub test2()

    Dim objIE As Object
    
    Set objIE = CreateObject("InternetExplorer.Application")
    
    objIE.Visible = True
    
    objIE.navigate GetSearchUrl("Excel")
    
    ' ページロード待ち
    Do While objIE.busy And objIE.readystate < 2
    Loop
    
    MsgBox "検索完了"
    
    objIE.Quit
    
    Set objIE = Nothing

End Sub