フォルダ内にある html ファイルの文字数／単語数を調べたい

WSHが一番適切と思いましたので、スクリプトを作ってみました。

Option Explicit

Const wdStatisticWords = 0
Const wdStatisticLines = 1
Const wdStatisticPages = 2
Const wdStatisticCharacters = 3
Const wdStatisticParagraphs = 4
Const wdStatisticCharactersWithSpaces = 5
Const wdStatisticFarEastCharacters =6

Dim strArg
Dim objFSO, objWord, objDoc, objRng
Dim objFolder, objFile

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objWord = CreateObject("Word.Application")
objWord.Visible = True  ' 表示が煩わしいならコメントにする

Wscript.Echo "ファイル名,文字数,単語数"
For Each strArg In WScript.Arguments
    Set objFolder = objFSO.GetFolder(strArg)

    For Each objFile In objFolder.Files
        ' htmも許すときは適宜変更ください
        If Lcase(Right(objFile.Name, 5)) = ".html" Then
            Set objDoc = objWord.Documents.Open(objFile.Path)
            Set objRng = objWord.ActiveDocument.Content
            ' ディレクトリ不要なら objFile.PathをobjFile.Nameに変更ください
            Wscript.Echo objFile.Path & "," & _
                objRng.ComputeStatistics(wdStatisticCharacters) & "," & _
                objRng.ComputeStatistics(wdStatisticWords)
            objWord.Documents.Close
            Set objDoc = Nothing
            Set objRng = Nothing
        End If
    Next
Next

objWord.Quit

●使い方

• 上のファイルを適当な名前で保存します（例.wordinfo.vbs）
• コマンドプロンプトで動かします（アクセサリ→コマンドプロンプト）

cscript wordinfo.vbs . aaaa >output.csv

wordinfo.vbsの後ろには、調べたいディレクトリを書きます（複数可）。

カレントなら「.」、相対なら「aaaa」のように、当然「C:\hproot」のように絶対パスもOKです。

最後に「>output.csv」のようにリダイレクトしてファイルに落としています。始めは、この「>output.csv」をつけなければ画面に表示されますので、その後でリダイレクトしてファイルに落とすのがいいかも知れません。

• csvを開いて先頭の何行かのゴミを削れば一覧表の完成です。
• 後はお好みに応じてパラメータを増やしたり、wordのちかちかをなくすれば、あっという間にファイルが作れます。