【ExcelVBA】Book1の科目毎・タイトル毎に、Book2へ転記するマクロです。画像をご覧いただけますか。

どのような方法でも処理ができればよいと思いますので、

「質問①のやりかたは邪道」ということはないと思いますが、

マクロを使用した例です（ご期待に反していたらすみません）。

Book1 の標準モジュールに下記を置き、実行してみてください。

Option Explicit

'--------------------------------------------------------
Sub MakeSumBook()
'--------------------------------------------------------
    Dim srcWB As Workbook
    Set srcWB = ThisWorkbook
    
    Dim dstWB As Workbook
    Set dstWB = Workbooks.Add()
    
    Dim srcWS As Worksheet
    Dim dstWS As Worksheet
    Set dstWS = dstWB.Worksheets(1)

    dstWS.Range("A1:C1") = Array("科目", "タイトル", "タイトルごとの合計")
'--- 各シートごとに処理
    For Each srcWS In srcWB.Worksheets
        addWSSum srcWS, dstWS
    Next
End Sub

'--------------------------------------------------------
Sub addWSSum(srcWS As Worksheet, dstWS As Worksheet)
'--------------------------------------------------------
    Dim startRow As Long
    startRow = dstWS.Range("A" & Rows.Count).End(xlUp).Row + 1
    
    Dim lastRow As Long
    lastRow = srcWS.Range("C" & Rows.Count).End(xlUp).Row
    
    
'--- タイトルを検索
    Dim myDic As Object
    Set myDic = CreateObject("Scripting.Dictionary")
    
    Dim c As Variant
    For Each c In srcWS.Range("C2:C" & lastRow)
        If Not c = Empty Then
            If Not myDic.Exists(CStr(c)) Then
                myDic.Add CStr(c), Null
            End If
        End If
    Next
        
    Dim myKey As Variant
    myKey = myDic.Keys
    
    dstWS.Range("B" & startRow).Resize(myDic.Count) _
        = Application.WorksheetFunction.Transpose(myKey)
    Set myDic = Nothing
        
'--- タイトル毎に集計
    Dim dstLastRow
    dstLastRow = dstWS.Range("B" & Rows.Count).End(xlUp).Row
    
    Dim r As Long
    For r = startRow To dstLastRow
        dstWS.Cells(r, "A").Value = srcWS.Name
        dstWS.Cells(r, "C").Value = WorksheetFunction.SumIf( _
            srcWS.Range("C2").Resize(lastRow - 1, 1), _
            dstWS.Cells(r, "B").Value, _
            srcWS.Range("B2").Resize(lastRow - 1, 1))
    Next
    
'--- 小計列を追加
    dstWS.Cells(r, "A").Value = srcWS.Name
    dstWS.Cells(r, "B").Value = "小計"
    dstWS.Cells(r, "C").Formula = "=SUM( C" & startRow & ":C" & dstLastRow & ")"
End Sub