ある法則を持って書かれたhtmlソースのテキストデータをEXCELでリスト化したいです。

Sub Macro1()
'   参照設定で以下２つにチェックをいれておくこと
'   Microsoft AxtiveX Data Objects x.x Library　 x.xは2.5以降（もう少し古いものでもＯＫかもしれませんが調べてません）
'   Microsoft VBScript Regular Expressions x.x   x.xは5.5以降
'   （実行時バインドに変更する場合はUTF-8やadTypeTextなどを数値指定に置き換える必要あり）
'
'   事前準備
    Dim fileName As String, chrCode As String, sheetName As String, strText As String
    fileName = "d:\ソース.html": '読み込むファイル（フルパスでの指定が必要です ActiveWorkbook.Path を使うと便利かもしれません）
    chrCode = "UTF-8": 'ファイルの文字コード
    strText = ""
    sheetName = "Sheet1": '書き込むシート
    startCell = "A1": 'セル内の書き込み開始位置
    
'   読み込み
    Dim st As ADODB.Stream
    Set st = New ADODB.Stream
    With st
        .Type = adTypeText: 'テキストモード
        .Charset = chrCode: 'ファイルの文字コード
        .Open: '開始
        .LoadFromFile (fileName): 'ファイルオープン
        strText = .ReadText(adReadAll): '一括読み込み
        .Close: '閉じる
    End With
    Set st = Nothing

'   シートのクリア
    Worksheets(sheetName).Select
    Cells.ClearContents: 'シート全体をクリアしますので、一部のみを削除する場合は変更が必要
    Range(startCell).Select
    
'   抜き出しとセルへの書き込み
    Dim re As RegExp, mc As MatchCollection, m As Match
    Set re = New RegExp
    With re
        .Pattern = "<tr>(\n|.)+?href=""(.+?)"">(.+?)<br>(.+?)</a>(\n|.)+?<td>(.+?)</td>(\n|.)*?</tr>": 'パターンはもう少しスマートになるかもしれません
        .IgnoreCase = True: '大文字小文字は区別しない
        .Global = True: '全体を検索対象とする
        .MultiLine = False: '複数行として取り扱わない
        Set mc = .Execute(strText): '実行
        For Each m In mc
            Selection.Value = m.SubMatches(1)
            Selection.Offset(0, 1).Value = m.SubMatches(2)
            Selection.Offset(0, 2).Value = m.SubMatches(3)
            Selection.Offset(0, 3).Value = m.SubMatches(5)
            Selection.Offset(1, 0).Select: '次の行にカーソル移動
        Next m
        Set mc = Nothing
        Set re = Nothing
    End With
End Sub

http://msdn.microsoft.com/ja-jp/library/cc364272.aspx

http://msdn.microsoft.com/ja-jp/library/cc392403.aspx