Excelで指定のキーワードを含む行を削除したいです。

こんな感じで、どうでしょうか。

Const SPEED_UP = False          ' True で速くなる

Const MAX_ROW = 300000          ' 突っ走るのが怖いので
Const KEYWORD = "りんご"

Sub Delete_Row_Include_Keyword()

    On Error GoTo ErrorHandler

    If SPEED_UP Then
        'ワークシートに描画しない
        Application.ScreenUpdating = False
    End If

    r = 1
    Do While r < MAX_ROW
        Set c = Cells(r, 7)
        If IsEmpty(c) Or c.Value = "" Then
            Exit Do
        End If

        If InStr(c.Value, KEYWORD) > 0 Then
            c.EntireRow.Delete
        Else
            r = r + 1
        End If
    Loop

FINAL:
    If SPEED_UP Then
        '結果を描画する
        Application.ScreenUpdating = True
    End If
    Exit Sub

ErrorHandler:
    GoTo FINAL


End Sub

行を削除したいシートを選択した状態で、このサブルーチンを実行してください。
先頭の方にある KEYWORD を、適当に変えてください。

G列のセルが、空の行が出てくると、そこで止まります。
処理が延々と終了しないのは、ちょっと恐いので、行数のカウントで最大の行数も指定してます。

SPEED_UP という定数を True にすると、画面の描画を止めるので、少し早くなります。
中程度のノートブックで、2500行くらいで 0.5秒くらいです。
それでも、30万行もあると、パソコンの性能にもよりますが、数分かかると思います。

バックアップを取ってから、試してみてください。

こんな感じでしょうか。

Public Sub DeleteRow()
Dim KeyWord As String
Dim R As Long
Dim MaxRow As Long

KeyWord = "er" '削除の条件

'Ｇ列がキーなのでＧ列で最終行を取得する
MaxRow = Range("G" & Cells.Rows.Count).End(xlUp).Row

'最後の行から１行目まで後ろからループさせることで読み飛ばしを回避する
For R = MaxRow To 1 Step -1
If Range("G" & R) = KeyWord Then
Rows(R).Delete
End If
DoEvents
Next

End Sub

１行目から順に・・・とすると削除すると行がずれてしまうので、後ろから順にまわすのがセオリーです。

そうそう、速くするには Application.ScreenUpdating = Falseにしておきましょう。　DoEventsで「応答なし」を回避しています。毎回のループではおおすぎるのならDoEventsの行を次のようにしてもいいでしょう。
If R Mod 100 = 0 Then
DoEvents
Application.StatusBar = R & " / " & MaxRow
End If
100行ごとにDoEventsとステータスバーへ進行状況のメッセージを書き込みます。
条件も「含む」であるなら Like とかInstrとかを使って書き直す必要があります。