hananeko_0回答ポイント 60pt

ExcelVBAです。

文字列の数字の羅列14文字を日付＋時刻の表示に
一括で変換したいのですが・・・

文字列：20080101000000　⇒　2008/01/01 00:00:00
範囲：任意の列にある２行目から最終行まで

・日付と時刻の間に半角スペースあり
　　2008/01/01 00:00:00⇒半角19文字
・表示形式は文字列
・数字は固定ではない（日付も時刻も内容はどれも異なる）

教えていただくと大変助かります。
宜しくお願い致します。

※ 有料アンケート・ポイント付き質問機能は2023年2月28日に終了しました。

ログインして回答する

ベストアンサー

Mook2008/10/31 09:13:05
満足60pt

下記は文字列として扱う例です。

変換対象範囲を選択して、実行してください。

'------------------------------------------------
' 14桁の文字列を日付形式の文字列として変換
'------------------------------------------------
Sub TimeConvAsStr()
'------------------------------------------------
    Dim dt As Double
    Dim r As Range
    For Each r In Selection
        If Len(r.Value) = 14 Then
            dt = DateSerial(CInt(Left(r.Value, 4)), CInt(Mid(r.Value, 5, 2)), CInt(Mid(r.Value, 7, 2))) _
                + TimeValue(Mid(r.Value, 9, 2) & ":" & Mid(r.Value, 11, 2) & ":" & Mid(r.Value, 13, 2))
            r.Value = Format(dt, "yyyy/mm/dd hh:mm:ss")
        End If
    Next
End Sub

ただ、せっかくの時間情報ですが文字列として扱いたいのでしょうか。

下記は時間情報として変換し、セルの書式で対応した例です。

'------------------------------------------------
' 14桁の文字列を日付時間型として保存
' 表示はデータの書式で設定
'------------------------------------------------
Sub TimeConvAsDateTime()
'------------------------------------------------
    Dim dt As Double
    Dim r As Range
    For Each r In Selection
        If Len(r.Value) = 14 Then
            dt = DateSerial(CInt(Left(r.Value, 4)), CInt(Mid(r.Value, 5, 2)), CInt(Mid(r.Value, 7, 2))) _
                + TimeValue(Mid(r.Value, 9, 2) & ":" & Mid(r.Value, 11, 2) & ":" & Mid(r.Value, 13, 2))
            r.NumberFormatLocal = "yyyy/mm/dd hh:mm:ss"
            r.Value = dt
        End If
    Next
End Sub