namaewa_5回答ポイント 200ptウォッチ 1

エクセル２００３

画像を参照下さい。
1.シートA、シートBがあります
2.ナンバーを軸（同一のナンバーは存在しません）に
　シートAに在ってシートBにないものはシートCには載せない
3.シートBに在ってAにないものはCに載せる
4.AとB両方にある場合はBの情報をCに載せる

これをマクロで、ボタンをポチと押せばサッサッサーとできるよう
お願いいたします。質問などはコメント欄にお書きください。

• はてなアカウントでログイン
• 無料ユーザー登録

ベストアンサー

• TransFreeBSD2012/01/07 18:30:38

  満足200pt

  
  Option Explicit
  
  Sub Macro1()
      ' データ対象範囲を指定
      ' 終了行は後で求める
      Const startCol = "A"
      Const indexCol = "G"
      Const endCol = "AU"
      Const startRow = 4
      Dim endRowA As Long
      Dim endRowB As Long
      Dim nowRowC As Long
      Dim indexA As Range
      Dim indexB As Range
      Dim sheetA As Worksheet
      Dim sheetB As Worksheet
      Dim sheetC As Worksheet
      Dim i As Long
      Dim res As Object
      ' それぞれのシートを指定
      Set sheetA = Worksheets("SheetA")
      Set sheetB = Worksheets("SheetB")
      Set sheetC = Worksheets("SheetC")
      ' シートAとシートBの最終行を求める
      endRowA = sheetA.Cells(sheetA.Rows.Count, indexCol).End(xlUp).Row
      endRowB = sheetB.Cells(sheetB.Rows.Count, indexCol).End(xlUp).Row
      ' シートCのデータの追加行
      nowRowC = startRow
      ' シートAとシートBのインデックスとなるナンバーの範囲
      Set indexA = sheetA.Range(sheetA.Cells(startRow, indexCol), sheetA.Cells(endRowA, indexCol))
      Set indexB = sheetB.Range(sheetB.Cells(startRow, indexCol), sheetB.Cells(endRowB, indexCol))
      
      ' まずシートAの上から順に見ていく
      For i = startRow To endRowA
          ' シートBから同じナンバーを探す
          Set res = indexB.Find(what:=sheetA.Cells(i, indexCol).Value, _
              LookIn:=xlValues, lookat:=xlWhole, MatchCase:=True, Matchbyte:=True)
          ' 見つかったらシートCにコピーする
          If Not res Is Nothing Then
              sheetB.Range(sheetB.Cells(res.Row, startCol), sheetB.Cells(res.Row, endCol)) _
                  .Copy Destination:=sheetC.Cells(nowRowC, startCol)
              nowRowC = nowRowC + 1
          End If
      Next i
      ' 次にシートBの上から順に見ていく
      For i = startRow To endRowB
          ' シートAから同じナンバーを探す
          Set res = indexA.Find(what:=sheetB.Cells(i, indexCol).Value, _
              LookIn:=xlValues, lookat:=xlWhole, MatchCase:=True, Matchbyte:=True)
          ' 見つからなかったらシートCにコピーする
          If res Is Nothing Then
              sheetB.Range(sheetB.Cells(i, startCol), sheetB.Cells(i, endCol)) _
                  .Copy Destination:=sheetC.Cells(nowRowC, startCol)
              nowRowC = nowRowC + 1
          End If
      Next i
  End Sub
  

  こんなところでいかがでしょうか。

  スター

  • 

    2件のコメントを見る

  • namaewa_5 2012/01/07 19:02:34

    回答ありがとうございます。
    水曜日に検証してみます！

    スター

  • namaewa_5 2012/01/11 20:55:06

    回答ありがとうございました。
    まだ試せていませんが追加・修正がありましたら
    IDコールさせていただきますのでその際はよろしくお願い致します。（もちろんポイントはお支払いしますので）
    
    リニューアルしてから本当、回答がつかなくなりました。。。
    しかも埋もれていく速さが半端ないです・・・あぁーぁー

    スター

その他の回答

この質問へのコメント

• きゃづみぃ2012/01/04 12:25:16
  回答できないけど、こんな簡単なの 誰か サッサッサーと作ってくれるだろうね。
  
• TransFreeBSD2012/01/04 15:27:14
  >>
  1.シートA、シートBがあります
  <<
  この時、シートCはどうなってるのでしょうか？
  シートCもあって、シートCにしか無いデータは残すと言う考えで間違いないですか？
• passivedokechi2012/01/04 21:05:13
  2.3.4の条件を満たすと結果的にBの内容をCに書き足すような処理になると思いますが、
  意図されている条件という認識でよいでしょうか？
• namaewa_52012/01/05 13:30:39
  >TransFreeBSD
  
  この時、シートCはどうなってるのでしょうか？
  シートC項目（タイトル）のみ表示されていると思っていただいて結構です
  
  
  
  >cno
  意図されている条件という認識でよいでしょうか？
  
  はい、その条件でお願いします
• TransFreeBSD2012/01/05 20:28:58
  シートCにデータがないのなら、シートBをまるまるコピーすれば済むと思うのですが、それで間違いないのでしょうか？
  一番簡単なのはシートCを消し、シートBを複製してシートCにすることだと思う。
• namaewa_52012/01/06 13:08:27
  説明が一つ足りなかったですね
  大元のデータがシートＡに入力されています。
  シートＢは番号がランダムな状態で落とされてシートＢに張り付けられています。
  シートＡの順番通りに並んだ状態でシートＡとシートＢのマッチングを行い
  シートＡの順番通りにシートＣにデータを反映させる。ということがやりたいのです。
  
  
  1.シートＡにある番号順に並ぶ
  2.シートＡになくてシートＢにある番号、つまり新たな番号は
  　シートＡの番号の最後に追加される並び順でシートＣに反映される
  3.シートＡにありシートＢにない番号、つまり削除される番号は
  　シートＡの番号順から削除（行削除）されシートＣに反映される
  
  あーやっぱり新しいはてなになってから回答がつかないなー
  規約違反として通知
• TransFreeBSD2012/01/07 12:43:02
  締め切りましたか。ようやく納得のいく仕様になったと思うのですが。
• namaewa_52012/01/07 16:23:02
  受付再開しました！よろしくお願いします
• きゃづみぃ2012/01/12 18:16:50
  ＞あーやっぱり新しいはてなになってから回答がつかないなー
  
  回答拒否になっていて 回答できないだけかと思う。
  
  

質問の情報

登録日時

2012-01-04 12:04:47

終了日時

2012-01-11 12:05:09

回答条件

1人2回まで

この質問のカテゴリ

• コンピュータ

この質問に含まれるキーワード

人気の質問

• 知らない人に突然話しかけられたらどうすれば良いですか？ 僕は高二の男です。今日祭りで友達を待っていた…匿名質問者118時間前
• Roblox Robux Generator https://www.linkedin.com/pulse/10000-free-robux-roblox-generator-unlimited-da…匿名質問者1日前
• マンガ展のリアルサイン会について マンガ展にて、とある漫画家さんのリアルサイン会イベントに当選させて…匿名質問者22日前
• Sssdsdda sasdasdadssads saddsaasd saddsa匿名質問者1日前
• 「この太ももってそんなに女の子の太ももに見えますか？ 前体育の着替え中にたまたま友達に…匿名質問者11日前

メニュー

• 質問一覧
• カテゴリ一覧
• 無料ユーザー登録
• 人力検索はてなトップ

PC版

• お問い合わせ
• ヘルプ
• お知らせ
• はてなトップ