• はてなアカウントでログイン
• 無料ユーザー登録

ベストアンサー

• cx202013/08/31 16:15:26

  満足100pt

  ADO は CursorLocation / CursorType / LockType の３つのプロパティの組み合わせによって挙動が変わってきます。
  データベースエンジンやドライバによって、サポートされていないオプションがあったりする為、推奨する設定を提示することができないのですが、組み合わせを変えて試してみてはいかがでしょうか。
  
  以下、参考情報です。

  ＜参考情報＞
  ■ Recordset オブジェクトの基本
  http://msdn.microsoft.com/ja-jp/library/cc376797.aspx
  
  ■ ADO カーソルを極める
  http://www.shoeisha.com/mag/windev/pdf/870507/windev0507_156_SQLServer.pdf
  
  ■ ADO 時代の非接続型データアクセス - とあるコンサルタントのつぶやき - Site Home - MSDN Blogs
  http://blogs.msdn.com/b/nakama/archive/2008/10/16/ado.aspx

  また、「行継続文字( _) を使いすぎています。」というエラーが出る場合は、
  以下のようにコードを修正してみてください。

  ' ステートメントを「_」により連結したケース（連結数に制限がある）
  Dim strSQL
  strSQL = "SELECT ..." & _
      "..." & _
      "..." & _
      "..." & _
      "..." & _
      "..."
  

  ' ステートメントを複数行に分割したケース（連結数に制限が無い）
  Dim strSQL
  strSQL = "SELECT ..."
  strSQL =  strSQL & "..."
  strSQL =  strSQL & "..."
  strSQL =  strSQL & "..."
  strSQL =  strSQL & "..."
  strSQL =  strSQL & "..."
  

  スター

  • 

    4件のコメントを見る

  • cx20 2013/08/31 21:55:32

    以下の環境にて ADO を用いた SELECT 時間（データ件数:500万件）を計測してみました。

    環境	バージョン
    OS	Windows 7
    SQLite	SQLite version 3.8.0.1
    Driver	SQLite3 ODBC Driver version 0.994.00.00

    テーブル定義

    No	列名	型	キー
    1	field1	INTEGER	PRIMARY KEY
    2	field2	TEXT

    実行SQL

    SELECT * FROM tb_test;
    

    テスト結果

    No	CursorLocation	CursorType	LockType	時間(秒)
    1	Server	ForwardOnly	ReadOnly	10
    2	Server	Keyset	ReadOnly	10
    3	Server	Dynamic	ReadOnly	10
    4	Server	Static	ReadOnly	10
    5	Client	ForwardOnly	ReadOnly	49
    6	Client	Keyset	ReadOnly	50
    7	Client	Dynamic	ReadOnly	50
    8	Client	Static	ReadOnly	50

    SQL が簡単な為か、とりあえず、数分かかるということはありませんでした。
    CursorLocation = adUseClient としたときの処理が遅いのは、500万件をクライアントカーソルとしてメモリ上にロードしている為と考えられます。
    もし、CursorLocation に adUseClient を利用されているのであれば、adUseServer に変更してみてください。
    
    また、TkSQLite が早い理由ですが、ADO に比べて、中間層が少ないのが起因しているのではないかと思います。

    ＜ADO 経由の DB 接続イメージ＞
             [ADO]
               |
    [Microsoft OLE DB Provider for ODBC]
               |
      [SQLite3 ODBC Driver]
               |
           [SQLite3]
    

    スター

  • cx20 2013/08/31 22:11:15

    参考までに計測に使用したスクリプト（VBScript）を添付します。

    ' File : SQLiteTest.vbs
    ' Usage : CScript //Nologo : SQLiteTest.vbs [Enter]
    Option Explicit
    
    Const DB_PATH = "C:\SQLite\db_test_5m"
    
    ' CursorLocationEnum
    Const adUseNone   = 1
    Const adUseServer = 2 ' 既定
    Const adUseClient = 3
    
    ' CursorTypeEnum
    Const adOpenForwardOnly = 0 ' 既定
    Const adOpenKeyset = 1
    Const adOpenDynamic = 2
    Const adOpenStatic = 3
    Const adOpenUnspecified = -1
    
    ' LockTypeEnum
    Const adLockReadOnly = 1
    Const adLockPessimistic = 2
    Const adLockOptimistic = 3
    Const adLockBatchOptimistic = 4
    Const adLockUnspecified = -1
    
    ' DataTypeEnum
    Const adInteger = 3
    Const adVarChar = 200
    Const adFldIsNullable = 32
    
    Dim g_rsTestCase
    
    Call Main()
    
    Sub Main()
        InitTestCase
        Dim rs
        Set rs = g_rsTestCase
        rs.MoveFirst
        While Not rs.BOF And Not rs.EOF
            ConnectTestByTestCaseRecordset rs
            rs.MoveNext
        Wend
    End Sub
    
    Sub InitTestCase()
        Set g_rsTestCase = CreateTestCaseRecordset()
        AddTestCase g_rsTestCase, 1, adUseServer, adOpenForwardOnly, adLockReadOnly, "Server,ForwardOnly,ReadOnly"
        AddTestCase g_rsTestCase, 2, adUseServer, adOpenKeyset,      adLockReadOnly, "Server,Keyset     ,ReadOnly"
        AddTestCase g_rsTestCase, 3, adUseServer, adOpenDynamic,     adLockReadOnly, "Server,Dynamic    ,ReadOnly"
        AddTestCase g_rsTestCase, 4, adUseServer, adOpenStatic,      adLockReadOnly, "Server,Static     ,ReadOnly"
        AddTestCase g_rsTestCase, 5, adUseClient, adOpenForwardOnly, adLockReadOnly, "Client,ForwardOnly,ReadOnly"
        AddTestCase g_rsTestCase, 6, adUseClient, adOpenKeyset,      adLockReadOnly, "Client,Keyset     ,ReadOnly"
        AddTestCase g_rsTestCase, 7, adUseClient, adOpenDynamic,     adLockReadOnly, "Client,Dynamic    ,ReadOnly"
        AddTestCase g_rsTestCase, 8, adUseClient, adOpenStatic,      adLockReadOnly, "Client,Static     ,ReadOnly"
    End Sub
    
    Function CreateTestCaseRecordset()
        Dim rs
        Set rs = CreateObject("ADODB.Recordset")
        rs.Fields.Append "CaseNo",              adInteger
        rs.Fields.Append "CursorLocationEnum",  adInteger
        rs.Fields.Append "CursorTypeEnum",      adInteger
        rs.Fields.Append "LockTypeEnum",        adInteger
        rs.Fields.Append "CaseName",            adVarChar, 255, adFldIsNullable
        rs.Open
        Set CreateTestCaseRecordset = rs
    End Function
    
    Function AddTestCase( ByRef rs, nCaseNo, nCursorLocation, nCursorType, nLockType, strCaseName )
        rs.AddNew
        rs("CaseNo")             = nCaseNo
        rs("CursorLocationEnum") = nCursorLocation
        rs("CursorTypeEnum")     = nCursorType
        rs("LockTypeEnum")       = nLockType
        rs("CaseName")           = strCaseName
        rs.Update
    End Function
    
    Sub ConnectTestByTestCaseRecordset( rs )
        Dim nCaseNo
        Dim nCursorLocation
        Dim nCursorType
        Dim nLockType
        Dim strCaseName
        nCaseNo         = rs("CaseNo")
        nCursorLocation = rs("CursorLocationEnum")
        nCursorType     = rs("CursorTypeEnum")
        nLockType       = rs("LockTypeEnum")
        strCaseName     = rs("CaseName")
        
        Call ConnectTestByTestCase( nCaseNo, nCursorLocation, nCursorType, nLockType, strCaseName )
    End Sub
    
    Sub ConnectTestByTestCase( nCaseNo, nCursorLocation, nCursorType, nLockType, strCaseName )
        Dim cn
        Set cn = CreateObject("ADODB.Connection")
        cn.ConnectionString = "DRIVER=SQLite3 ODBC Driver;Database=" & DB_PATH
        cn.Open
        cn.CursorLocation = nCursorLocation
        
        Dim strSQL
        strSQL = "SELECT * FROM tb_test;"
        
        Dim dtStart ' 開始時間
        Dim dtEnd   ' 終了時間
        Dim dtDiff  ' 処理時間
    
        Dim rs
        Set rs = CreateObject("ADODB.Recordset")
        dtStart = Now 
        ' recordset.Open Source, ActiveConnection, CursorType, LockType, option
        rs.Open strSQL, cn, nCursorType, nLockType
        dtEnd = Now
        dtDiff = DateDiff("s", dtStart, dtEnd )
        
        ' 計測結果表示
        WScript.Echo nCaseNo & "," & strCaseName & "," & dtDiff
    End Sub
    

    スター

  • FujiiRock 2013/09/01 00:58:11

    おおー(^^)
    ありがとうございますっ！
    おかげさまで、カーソルを変えたら改善されました！
    また、深いところも教えていただきありがとうございます。
    サンプルコードも読みやすくて勉強になりました～

    スター

  • cx20 2013/09/01 11:36:43

    蛇足ですが、ADO のレコードセットの内容を Excel のシートに転記したい場合、「CopyFromRecordset」メソッドが高速なのでお勧めです。

    ActiveSheet.Range("A1").CopyFromRecordset rs
    

    ＜参考情報＞
    ■ オートメーションを使用して ADO レコードセットのデータを Excel に転送する方法
    http://support.microsoft.com/kb/246335/ja

    スター

その他の回答

• だわかき2013/08/31 15:59:29

  満足10pt

  SQLite ODBC Driverが高速化されていないためです。
  
  場合によってはSQLite to Excelを使った方が早いかもしれません。
  
  SQLite to Excel
  http://www.vector.co.jp/soft/winnt/business/se481602.html

  スター

この質問へのコメント

質問の情報

登録日時

2013-08-31 14:21:15

終了日時

2013-09-01 00:58:37

回答条件

1人5回まで

この質問のカテゴリ

• コンピュータ

この質問に含まれるキーワード

人気の質問

• 音楽のドレミですが、ドイツでは、ABCです（アーベーツェー）。英米でも、ABC（エービーシー）です。イタリ…匿名質問者9時間前
• こんなものありますか？　ダイソーの「吊り下げワイシャツ収納」みたいなもの。これは、入れるところが、５…匿名質問者1日前
• 【次の予想は定理か】位数３の体上のn次元ベクトル空間に於いて、その零でない相異なる(n+1)個の元の組Vを{…くろょ1日前
• 英語等の先生など外国語の指導者の方、また、帰国子女の方、お伺いさせてください。外国語は外国語として理…匿名質問者6時間前
• 再帰動詞と代名動詞は、おなじですか？　フランス語では違うけれど、スペイン語やイタリア語では同じ？とい…匿名質問者1日前

メニュー

• 質問一覧
• カテゴリ一覧
• 無料ユーザー登録
• 人力検索はてなトップ

PC版

• お問い合わせ
• ヘルプ
• お知らせ
• はてなトップ