• はてなアカウントでログイン
• 無料ユーザー登録

ベストアンサー

• Mook2013/12/30 00:46:08

  満足500pt

  こんなことでしょうか。
  

  Option Explicit
  
  Sub 集計()
      Dim myWS As Worksheet
      Set myWS = ActiveSheet
      
      Dim wsh
      Set wsh = CreateObject("WScript.Shell")
  
  '// ★ デスクトップ上のフォルダ名を設定  ： データフォルダ を変更
      Dim dtPath
      dtPath = wsh.SpecialFolders("Desktop") & "\データフォルダ"
  
      Dim fso
      Set fso = CreateObject("Scripting.FileSystemObject")
  
      myWS.Columns("B").Font.ColorIndex = 3
  
      Dim file
      Dim xName
      Dim dstCell As Range
      Dim srcCell As Range
      
      Application.ScreenUpdating = False
      Application.Calculation = xlCalculationManual
      
      For Each file In fso.GetFolder(dtPath).Files
          If InStr(file.Name, ".xls") > 0 Then
              xName = StrConv(Left(file.Name, InStr(file.Name, ".xls") - 1), vbNarrow)
              Set dstCell = myWS.Columns("A").Find(xName, lookat:=xlWhole)
              If dstCell Is Nothing Then
                  Set dstCell = myWS.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0)
                  dstCell.Value = xName
              End If
              With Workbooks.Open(file.Path)
                  Set srcCell = .Worksheets(1).Columns("A").Find("合計")
                  dstCell.Offset(0, 1).Font.ColorIndex = 1
                  If srcCell Is Nothing Then
                      dstCell.Offset(0, 1).Value = "合計がありません"
                  Else
                      dstCell.Offset(0, 1).Value = srcCell.Offset(0, 1).Value
                  End If
                  .Close SaveChanges:=False
              End With
          End If
      Next
      Application.Calculation = xlCalculationAutomatic
      Application.ScreenUpdating = True
  End Sub
  

  スター

  • 

    1件のコメントを見る

  • にゃんころね 2013/12/30 15:48:10

    希望通りにいきました。ありがとうございます。

    スター

その他の回答

この質問へのコメント

質問の情報

登録日時

2013-12-29 18:22:49

終了日時

2013-12-30 15:48:30

回答条件

1人5回まで

この質問のカテゴリ

• コンピュータ
• 学習・教育

この質問に含まれるキーワード

人気の質問

• この英文どうなってますか？ The boy seemed to be waiting for his mother to come.（その少年は母親が来…匿名質問者111日前
• 不定詞の形容詞的用法らしいんですけど、副詞的用法と書いたら✖️ですか？ I want to buy a book to read …匿名質問者111日前
• 日向陽葵という○V女優が好きなのですが似ている○V女優はいますか匿名質問者14時間前
• 共通テストで使われるプログラミング言語は共通テスト特有の言語と聞いたのですが、受験勉強で身につけたプ…匿名質問者114時間前
• 内定してほしいポケモンはいますか？匿名質問者14時間前

メニュー

• 質問一覧
• カテゴリ一覧
• 無料ユーザー登録
• 人力検索はてなトップ

PC版

• お問い合わせ
• ヘルプ
• お知らせ
• はてなトップ