多数のファイルがあるフォルダのファイルから、ファイル名.拡張子 0Byteの空ファイルを作成したい

このようなフリーツールを探しています。どなたかご存知の方教えていただければ！よろしくお願いします。

ログインして回答する

ベストアンサー

匿名回答3号2017/11/13 18:28:33
こんなんでどうでしょ
```
@echo off
setlocal enabledelayedexpansion

rem ==========
rem コピー元↓
rem ==========
set FROM=c:\hoge

rem ==========
rem コピー先↓
rem ==========
set DEST=c:\copy

call :COUNT %FROM%
if not exist "%DEST%\*" md "%DEST%"
call :COPY "%FROM%"
for /F "delims=" %%D in ('dir/b/a:d/s "%FROM%"') do call :COPY "%%D"
goto :EOF

:COPY
set FOLDER=%~1
set TOFOLDER=%DEST%!FOLDER:~%COUNT%!
if not exist "%TOFOLDER%\*" md "%TOFOLDER%"
for %%F in ("%FOLDER%\*.*") do copy nul "%TOFOLDER%\%%~nxF"
goto :EOF

:COUNT
set STR=%*
set COUNT=0
:LP
if "%STR%"=="" goto :EOF
set /A COUNT=%COUNT%+1
set STR=%STR:~1%
goto LP
```
http://d.hatena.ne.jp/papermelt/20110919/1316404963
何故かURL必須だったのでとりあえず作る時に見たページを
- 3件のコメントを見る
- 匿名質問者 2017/11/13 18:53:02
  
  ━━(ﾟдﾟ；)━━
  こ、これはコピー元とコピー先を指定すればできるってやつですか…？
  さっそく使ってみます！
- 匿名質問者 2017/11/13 19:02:28
  
  できた…できました…！
  完璧かつパーフェクトな仕事ぶり、ありがとうございました（感謝
- 匿名質問者 2017/11/13 19:04:46
  
  匿名1号さん、2号さん、匿名回答1号さん、ありがとうございました！
  1号さんの回答をベストアンサーにして〆たいと思います。
  神をかみまみた（垣間見た）思いです。

その他の回答

この質問へのコメント

匿名回答1号2017/11/12 16:42:29

その説明では何を求めてるのかさっぱり分からない
フリーソフトっていうのは自作したものが
他の人にも需要があるだろうと親切心からタダで公開するんであって
オンリーワンな挙動をする特殊なプログラムを求めてるなら
自作するか金払って作ってもらうかのどちらかしかないよ
匿名質問者2017/11/12 16:48:26

さっぱりでしたか…それはすみませんでした。
例を挙げてみれば、C:\hoge\ フォルダに

hoge.txt
nomi.jpg
text.gif
...
という風なファイル群100個ほどあるとして、これらのフォルダ構造を再現しながら、0バイトの

hoge.txt
nomi.jpg
text.gif
...

という空ファイルをC:\copy フォルダに取得したいのです。
匿名回答1号2017/11/12 17:04:30

需要があると思えば誰かが公開している可能性はある
でも0バイトのファイルなんて普通の人からすれば単なるゴミです
仮にそうしたプログラムを自作する人がいたとして
きっとこれはほかの人も望んでいるソフトに違いないと
公開するような人はまずいないと思うんだ
もしファイル構造をテキストファイルに書き出すだけでもいいのなら
コマンドラインに以下のように入力すれば事足りるからね

dir C:\hoge > copy.txt

でもやはりファイル構造を再現したいと思う人はまずいないと思うよ
だってそんなの作成したって削除する以外に何か使い道があるように思えないもの
匿名質問者2017/11/12 17:20:05

ありがとうございます！dirコマンドでファイル名を書き出すことはできるんですね。
これでやってみようと思います。
匿名回答1号2017/11/12 17:33:50

正確にはdirコマンドでじゃなく
結果の出力先をモニターからファイルに変更しただけです
http://cmd-pro.com/tec_redirect.html
匿名回答2号2017/11/12 18:03:30

ちなみに0バイトファイルは　type nullで作成できます
下記サンプル1
https://pf-j.sakura.ne.jp/program/dos/doscmd/dev_nul.htm
匿名回答1号2017/11/12 18:24:00

１ファイルだけでいいならわざわざコマンドライン開くまでもなく
右クリックメニューの新規作成からテキストドキュメントを選ぶだけで作れる
匿名質問者2017/11/12 18:26:48

2号さんもありがとうございます！コマンドの組み合わせでできないかなぁという気持ちですが…1号さんの方法でファイル名を取得したら、その後は手作業でいくしかなさそうですね。

多数のファイルがあるフォルダのファイルから、ファイル名.拡張子 0Byteの空ファイルを作成したい

ベストアンサー

匿名回答3号2017/11/13 18:28:33

匿名質問者 2017/11/13 18:53:02

匿名質問者 2017/11/13 19:02:28

匿名質問者 2017/11/13 19:04:46

その他の回答

この質問へのコメント

この質問への反応（ブックマークコメント）

質問の情報

この質問のカテゴリ

この質問に含まれるキーワード

人気の質問

メニュー

PC版