orekojinn回答ポイント 3000ptウォッチ

指定条件フォルダ内の指定ファイルの自動コピーをしたいです。

以前類似の質問をし、回答でVBスクリプトのコードを書いていただきました。
http://q.hatena.ne.jp/1526039092
コードを流用できそうですが私は知識が無くうまくいきませんでした。

今回実現したいことは
フォルダAの下に多数のフォルダA-1,A-2,A-3等を作り、それらの中に複数枚（0～30枚）の画像ファイルを入れます。
このフォルダ群の中で11枚以上の画像ファイルが入っているフォルダを
フォルダBの下にコピーしたいです。
ただし番号の若いファイル10枚目まではコピーせずに11枚目以降のみをコピーします。

例えば
フォルダAの下のフォルダA-1には画像ファイルが8枚,A-2には10枚,A-3には13枚の場合には
フォルダBにフォルダA-3のフォルダのみをコピーし、そのフォルダの中にはA-3の中に入っていた画像ファイルのうち若いファイル名から数えて
11枚目～13枚目の3枚のみをコピーする。
というものです。

具体的なコードを記載いただけると大変助かります。
どうぞよろしくお願いいたします。
なおOSはwindows10です。

• はてなアカウントでログイン
• 無料ユーザー登録

ベストアンサー

• Silvanus2019/09/12 18:06:25

  満足3000pt

  お試し下さい。
  

  Option Explicit
  
  Dim objRecSet
  Dim objFileSys
  Dim objFolder
  Dim objSubFolder
  Dim objSubFolders
  Dim strPath
  Dim intCnt
  Dim intNFiles
  Dim strFileName
  Dim strFNSorted
  
  Const INT_N_FILES = 10 ' スキップするファイル数
  Const STR_PATH_SRC = "C:\XXXXX" ' コピー元 親フォルダ
  Const STR_PATH_DST = "C:\YYYYY" ' コピー先 親フォルダ
  
  Const AD_VAR_CHAR = 200 ' adVarChar, ADO DataTypeEnum
  
  Set objFileSys = CreateObject("Scripting.FileSystemObject")
  Set objFolder = objFileSys.GetFolder(STR_PATH_SRC)
  Set objSubFolders = objFolder.SubFolders
  
  For Each objSubFolder In objSubFolders
    intNFiles = objSubFolder.Files.Count
    If objSubFolder.Files.Count > INT_N_FILES Then
      strPath = STR_PATH_DST & "\" & objSubFolder.Name
      If Not objFileSys.FolderExists(strPath) Then
        objFileSys.CreateFolder(strPath)
      End If
      Set objRecSet = CreateObject("ADODB.Recordset")
      Call objRecSet.Fields.Append("FileName", AD_VAR_CHAR, 255)
      Call objRecSet.Open()
      For Each strFileName In objSubFolder.Files
        Call objRecSet.AddNew()
        objRecSet.Fields("FileName").Value = strFileName.Name
      Next
      Call objRecSet.Update()
      objRecSet.Sort = "FileName ASC"
      strFNSorted = objRecSet.GetRows()
      Call objRecSet.Close()
      Set objRecSet = Nothing
      For intCnt = INT_N_FILES To intNFiles - 1
        Call objFileSys.CopyFile(objSubFolder & "\" & strFNSorted(0, intCnt), strPath & "\" & strFNSorted(0, intCnt), True)
      Next
    End If
  Next
  
  MsgBox "処理を終了しました。", vbOkOnly + vbInformation, "終了"
  

  スター

  • 

    1件のコメントを見る

  • orekojinn 2019/09/13 16:27:12

    ただいま動かしてみました。希望通りの動きをすることを確認しました。
    いつもありがとうございます。
    m(_ _)m

    スター

その他の回答

この質問へのコメント

• Silvanus2019/09/10 18:26:53
  「若いファイル名」というのは具体的にどういうことなんでしょうか？
• orekojinn2019/09/10 19:09:11
  あっ！　Silvanusさま
  どうも　先日もテキストファイルの保存形式の件でお世話になりました。
  ありがとうございました。
  
  「若いファイル名」という言い方が間違ってました。。すみません。
  何と言えばよいのでしょうか。
  フォルダの中に
  A001.JPG
  A002.JPG
  A003.JPG
  A004.JPG
  A005.JPG
  A006.JPG
  A007.JPG
  A008.JPG
  A010.JPG
  A011.JPG
  A100.JPG
  A111.JPG
  
  上記の12個の画像ファイルがある場合はこの通りの順番に並ぶかと思います。
  このファイルの並びの1番目から10番目はコピーの必要が無く
  11番目以降のみをコピーしたいです。
  上の例では
  A100.JPG
  A111.JPG
  のみがコピーされれば良いです。
  現在は12個の画像が全てコピーされます。
  
• Silvanus2019/09/10 22:01:13
  此方こそ御世話になってます。
  「英字1文字＋数字3桁」あるいは「末尾が数字3桁」という様にフォーマットが定まっているのでしょうか。いないのでしょうか。
• orekojinn2019/09/11 08:42:35
  フォーマットは定まっています。.JPGの左にある5桁の数字が可変し、他は固定です。
  実際のファイル名のサンプルを記載します。
  IMG_01504.JPG
  IMG_09526.JPG
  IMG_09536.JPG

質問の情報

登録日時

2019-09-09 20:46:35

終了日時

2019-09-13 16:27:31

回答条件

1人5回まで

この質問のカテゴリ

• コンピュータ
• インターネット

この質問に含まれるキーワード

人気の質問

• この英文どうなってますか？ The boy seemed to be waiting for his mother to come.（その少年は母親が来…匿名質問者112日前
• 不定詞の形容詞的用法らしいんですけど、副詞的用法と書いたら✖️ですか？ I want to buy a book to read …匿名質問者112日前
• 日向陽葵という○V女優が好きなのですが似ている○V女優はいますか匿名質問者16時間前
• 共通テストで使われるプログラミング言語は共通テスト特有の言語と聞いたのですが、受験勉強で身につけたプ…匿名質問者116時間前
• 内定してほしいポケモンはいますか？匿名質問者17時間前

メニュー

• 質問一覧
• カテゴリ一覧
• 無料ユーザー登録
• 人力検索はてなトップ

PC版

• お問い合わせ
• ヘルプ
• お知らせ
• はてなトップ