VBについて質問します。

前の人のWSHを参考に変更しました。

３つのvbsファイルで実現しています。

④は、ボタンは付けられないので、最初にスタートするかを聞いて、その後は停止するときにボタンを押すという、簡易方法で実現しています。

下記は適宜変更してください。

設定ファイル：Mytimer.ini

音ファイル：Notifyにしました。Vistaにもきっとあると思います。

●メイン　timer.vbs

Option Explicit

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Const iniFile = "Mytimer.ini"
Const strMCommand = "WScript.exe ""timerM.vbs"" "
Const WshRunning = 0

Dim nn, rc
Dim objShell, objExec, objFSO, objInput, objOutput

Set objFSO = wscript.CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Wscript.Shell")

nn = ""
On Error Resume Next

' 時間設定を読み取りモードで開いてデフォルトに使う
Set objInput = objFSO.OpenTextFile(iniFile, ForReading)
nn = objInput.ReadLine
objInput.Close
On Error GoTo 0

nn = InputBox("""/""区切りで時間を入力", , nn)
    If IsEmpty(nn) Then wscript.Quit

' 時間設定を上書き
Set objOutput = objFSO.CreateTextFile(iniFile)
objOutput.WriteLine (nn)
objOutput.Close

rc = MsgBox("続けますか？", vbYesNo)
If rc = vbYes Then
    Set objExec = objShell.Exec(strMCommand & nn)
    If MsgBox("タイマー稼働中" & vbCrLf & vbCrLf & "停止は、OKを押してください", vbOKOnly, "Myタイマー") = vbOK Then
        If objExec.Status = WshRunning Then objExec.Terminate
    End If
End If

●timerM.vbs

Option Explicit

Const strSCommand = "timerS.vbs "

Dim nn2, t
Dim objShell

Set objShell = CreateObject("Wscript.Shell")
nn2 = Split(WScript.Arguments(0), "/")
For t = 0 To UBound(nn2)
    wscript.sleep (60000 * nn2(t))
    objShell.Run strSCommand & nn2(t), 0, False
Next

●timerS.vbs

Option Explicit

Const strSoundFile = "C:\windows\Media\Notify.wav"

Dim objShell
Dim strCommand

Set objShell = CreateObject("Wscript.Shell")
strCommand = "sndrec32 /play /close " & "" & strSoundFile & ""
objShell.Run strCommand, 0, False
WScript.Sleep 1000
MsgBox WScript.Arguments(0) & "分経過しました" & vbCrLf & Time, vbMsgBoxSetForeground + vbSystemModal

スクリプトを変更しました。

＞音を変更したいのですがその手順を教えてください。

Step1.C:\windows\Mediaの中で好きなファイル名を探す（右クリックで再生）

Step2.timerS.vbs中の下記を好きなファイル名に変える。

Const strSoundFile = "C:\windows\Media\Notify.wav"

要望3は、メインのウィンドウのことと思います。

アクティブウィンドウは、他ウィンドウをクリックすれば自動で非アクティブになるので、スクリプト側では何も対応していません。

●メイン　timer.vbs

Option Explicit

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Const iniFile = "Mytimer.ini"
Const strMCommand = "WScript.exe ""timerM.vbs"" "
Const WshRunning = 0

Dim nn, rc
Dim objShell, objExec, objFSO, objInput, objOutput

Set objFSO = wscript.CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Wscript.Shell")

nn = ""

' 時間設定を読み取りモードで開いてデフォルトに使う
' ファイルがなかったらエラー無視して続ける
On Error Resume Next
Set objInput = objFSO.OpenTextFile(iniFile, ForReading)
nn = objInput.ReadLine
objInput.Close
On Error GoTo 0

nn = InputBox("""/""区切りで時間を入力", , nn)
If IsEmpty(nn) Then wscript.Quit

' 時間設定を上書き
Set objOutput = objFSO.CreateTextFile(iniFile)
objOutput.WriteLine (nn)
objOutput.Close

' タイマーのサブプロセスを動かす
Set objExec = objShell.Exec(strMCommand & nn)
If MsgBox("タイマー稼働中" & vbCrLf & vbCrLf & "停止は、OKを押してください", vbOKOnly, "Myタイマー") = vbOK Then
    If objExec.Status = WshRunning Then objExec.Terminate
End If

●timerM.vbs

Option Explicit

' アラーム時に鳴らすファイルの名前
Const strSoundFile = "C:\windows\Media\Notify.wav"

Dim nn2, t, strCommand
Dim objShell

Set objShell = CreateObject("Wscript.Shell")
strCommand = "sndrec32 /play /close " & "" & strSoundFile & ""

nn2 = Split(wscript.Arguments(0), "/")
Do While True
    For t = 0 To UBound(nn2)
        wscript.sleep (60000 * nn2(t))
        objShell.Run strCommand, 0, False
        objShell.AppActivate "Myタイマー"
    Next
Loop