Perlでファイルリストを出来るだけ高速に取得する方法を教えてください。

perl でできなくはないと思いますが、フォルダ名やファイル名に日本語が含まれている場合

どうしても文字コードの問題が付きまといます。

餅は餅屋ではないですが Windows であれば VBS 等、ファイルシステムとの親和性の高いものを

利用してはどうでしょうか。

perl から利用する場合は、コメントした通りです。

#!C:/Perl/bin/perl -w

print system("CScript //nologo \"C:\\test\\listFile.vbs\" \"C:\\Test\\\"");

下記は、

>「第○階層まで」としたり、　　　　　　　　　　depthLimit で指定

>「○○と付くフォルダは除外する」という指定　　ignoreFolder で指定

を vbs で実装した例です。

【listFile.vbs】

Option Explicit

'----------------------------------------
Const depthLimit = 3
'--- 処理をしないフォルダに含まれる文字を「,」区切りで列挙
Const ignoreFolder = "test,temp,log"

'----------------------------------------
Dim fso, rootFolder, iFolders
Set fso = CreateObject("Scripting.FileSystemObject")

'--- 引数の確認
If WScript.Arguments.Count > 0 Then
    rootFolder = WScript.Arguments.item(0)
Else
'--- 指定がなければ C のルートを設定
    rootFolder = "C:\"
End If

'--- フィルタ文字列を配列に変換
iFolders = Split( ignoreFolder, "," )

'--- 表示処理
printFolder 0, fso.getFolder( rootFolder )

'----------------------------------------
Sub printFolder( depth, objFolder )
'----------------------------------------
    WScript.Echo objFolder.Path & "\"
    If depth >= depthLimit Then
        Exit Sub
    End If

    Dim sFolder, sFile
'--- 指定の文字を含むフォルダは処理をしない
    For Each sFolder In iFolders
    If InStr( objFolder.Name, sFolder ) > 0 Then
        Exit Sub
    End If
    Next

'--- フォルダ内のファイルの列挙
    For Each sFile In objFolder.Files
        WScript.Echo sFile.Path
    Next

'--- サブフォルダの処理
    For Each sFolder In objFolder.SubFolders
        printFolder depth + 1, sFolder
    Next
End Sub

インデントが見やすいのでコメントでなく回答させていただきましたが、

あくまで perl で処理を行うことが目的で、ということでしたらポイント不要です。

（他に回答なければキャンセルください。）

ファイル、フォルダのオプションを第二引数として追加した例です。

コマンド上で

CScript //nologo listFolder listFile.vbs ファイルパス　　[-folder | -file]

のように指定します。

Option Explicit

'----------------------------------------
Const depthLimit = 3
'--- 処理をしないフォルダに含まれる文字を「,」区切りで列挙
Const ignoreFolder = "test,temp,log"

'----------------------------------------
Dim fso, rootFolder, iFolders
Set fso = CreateObject("Scripting.FileSystemObject")

'--- 引数の確認
If WScript.Arguments.Count > 0 Then
    rootFolder = WScript.Arguments.item(0)
Else
'--- 指定がなければ C のルートを設定
    rootFolder = "C:\"
End If

Dim mode
mode = "BOTH"
If WScript.Arguments.Count > 1 Then
    If UCase( WScript.Arguments.item(1) ) = "-FOLDER" Then
        mode = "FOLDER"
    End If
    If UCase( WScript.Arguments.item(1) ) = "-FILE" Then
        mode = "FILE"
    End If
End IF

'--- フィルタ文字列を配列に変換
iFolders = Split( ignoreFolder, "," )

'--- 表示処理
printFolder 0, fso.getFolder( rootFolder )

'----------------------------------------
Sub printFolder( depth, objFolder )
'----------------------------------------
    If mode <> "FILE" Then
        WScript.Echo objFolder.Path & "\"
    End If

    If depth >= depthLimit Then
        Exit Sub
    End If

    Dim sFolder, sFile
'--- 指定の文字を含むフォルダは処理をしない
    For Each sFolder In iFolders
    If InStr( objFolder.Name, sFolder ) > 0 Then
        Exit Sub
    End If
    Next

'--- フォルダ内のファイルの列挙
    If mode <> "FOLDER" Then
        For Each sFile In objFolder.Files
            WScript.Echo sFile.Path
        Next
    End If
'--- サブフォルダの処理
    For Each sFolder In objFolder.SubFolders
        printFolder depth + 1, sFolder
    Next
End Sub