エクセル（VBA）に関して質問です。

EXCEL のソートの仕様により、並べ替え順は提示されたサンプルと異なりますが、

内容に関しては同等の結果になると思います。

不明な点がありましたら、コメントください。

Option Explicit
Sub Aiomac()
    Const DATA_START_LINE = 2

    Dim i As Long
'--- Step 1 ソート
    Columns("A:AG").Sort _
        Key1:=Range("AG1"), Order1:=xlAscending, _
        Key2:=Range("AF1"), Order2:=xlAscending, _
        Header:=True, Orientation:=xlTopToBottom, SortMethod:=xlPinYin
    
    Dim lastRow As Long
    lastRow = Range("AF" & Rows.Count).End(xlUp).Row
    
'--- Step 2 データ転記
    Dim pCode As String
    Dim bOverWrite As Boolean
    Dim srcRow As Long
    For i = DATA_START_LINE To lastRow
        If Cells(i, "AG").Value = pCode Then
            If bOverWrite = True And Cells(i, "AF") = 1 Then
                Range("A" & srcRow).Resize(1, 31).Copy _
                    Destination:=Range("A" & i).Resize(1, 31)
                Cells(i, "AH") = "再出品"
            End If
        Else
            If Cells(i, "AF").Value = 0 Then
                bOverWrite = True
                pCode = Cells(i, "AG").Value
                srcRow = i
            Else
                bOverWrite = False
            End If
        End If
    Next
    
'--- Step 3 行削除
    For i = lastRow To DATA_START_LINE Step -1
        If Cells(i, "AF") = 0 Then
            Rows(i).Delete
        End If
    Next
End Sub