エクセルについて教えてください。

できなくはないのですがリンクが発生するので、ファイルの変更や追加に対して柔軟に対応できず、

問題が発生する可能性もあります。

対象となるファイル数は多いのでしょうか？

あまり多い数でなければ、対象となるシートを一つのファイルに集め、ブック内で串刺し集計しては

どうでしょうか。

下記はあるフォルダ内にあるシートを一つのブックに集めるマクロです。

Const FolderPath = "C:\Data"
Const SheetName = "集計"

Sub getSheets()
    Dim dstWB As Workbook
    Set dstWB = Workbooks.Add()
    
    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim ff As Object
    For Each ff In fso.getFolder(FolderPath).Files
        If UCase(fso.GetExtensionName(ff.Path)) = "XLS" Then
            Set wb = Workbooks.Open(ff.Path)
            wb.Worksheets(SheetName).Copy before:=dstWB.Worksheets(1)
            wb.Close
            dstWB.Worksheets(1).Name = Replace(LCase(ff.Name), ".xls", "")
        End If
    Next
End Sub

http://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q1110478...

ファイル数が３００ということで、１つのブックにまとめるのは現実的ではないようですので、

VBAで個々にカウントするコードにしてみました。

セルごとに指定したデータの数をカウントして表示しています。

（そのため同じセルの位置に○と×のように違うデータがあっても合計しています。）

Excelのあるフォルダのパス、シート名、データの種類を実際の値に変更して実行してみてください。

Sub CountData()
    'Excelファイルのあるフォルダを指定
    Const FolderPath = "C:\Documents and Settings\hogehoge\デスクトップ\test"
    '集計するシート名を指定
    Const SheetName = "Sheet1"
    
    Dim i As Integer
    Dim str As String
    Dim wb As Workbook
    Dim r As Range
    Dim fso As Object
    Dim ff As Object
    Dim myData As Variant
    Dim sh As Worksheet
    
    Set sh = ActiveSheet
    
    'カウントするデータを種類を指定してください
    myData = Array("○", "×", "①", "②", "③", "④", "⑤")
        
    Set fso = CreateObject("Scripting.FileSystemObject")

    For Each ff In fso.getFolder(FolderPath).Files
        If UCase(fso.GetExtensionName(ff.Path)) = "XLS" Then
            Set wb = Workbooks.Open(ff.Path)
                For Each r In wb.Worksheets(SheetName).UsedRange
                    For i = 0 To UBound(myData)
                        If r.Value = myData(i) Then
                            sh.Range(r.Address).Value = sh.Range(r.Address).Value + 1
                        End If
                    Next i
                Next
            wb.Close
        End If
    Next
    
End Sub