vbsで指定したフォルダへの保存。


以下サイト、No.5にあるスプリクトで、保存先をディスクトップ上の
あらかじめ作成しておいたフォルダに保存するには
どのようにしたらいいのでしょう?

(仮にフォルダ名を「保存フォルダ」として)

http://oshiete.goo.ne.jp/qa/2259841.html?ans_count_asc=1

回答の条件
  • 1人2回まで
  • 13歳以上
  • 登録:2011/02/11 16:32:31
  • 終了:2011/02/11 18:06:51

ベストアンサー

id:asuka645 No.1

あすか回答回数856ベストアンサー獲得回数972011/02/11 17:21:40

ポイント100pt

下記のようになります。

Const adTypeBinary = 1
Const adSaveCreateNotExist = 1
Const adSaveCreateOverWrite = 2

For i= 0 To 6 '現在時刻から6時間後まで
    dYear = Fmt(Year(Now),4)
    dMonth = Fmt(Month(Now),2)
    dDay = Fmt(Day(Now),2)
    dHour = Fmt(Hour(Now),2)
    dMinute = "00"
    dName = dYear & dMonth & dDay & dHour & dMinute & "-0" & i & ".png"
    sSource = "http://www.jma.go.jp/jp/radame/imgs/prec/000/" & dName 'ダウンロード元
    Set ws = WScript.CreateObject("WScript.Shell") '特殊フォルダ名の取得
    desktopDir = ws.SpecialFolders("Desktop") 'デスクトップの実体
    sDest = desktopDir & "\保存フォルダ\" & dName 'コピー先
    Set oHTTP = WScript.CreateObject("Msxml2.XMLHTTP")
    oHTTP.Open "GET", sSource, False
    oHTTP.Send
    Set Stream = WScript.CreateObject("Adodb.Stream")
    Stream.Type = adTypeBinary
    Stream.Open
    Stream.Write oHTTP.responseBody
    Stream.Savetofile sDest, adSaveCreateOverWrite
Next

Function Fmt(num, digit) '0を頭につけて桁数を合わせる(例:6→06)
    Fmt = Right(String(digit, "0") & num, digit)
End Function
id:sunfkin22

ありがとうごいます!

希望通り、保存するできるようになりました!

2011/02/11 18:05:44

コメントはまだありません

この質問への反応(ブックマークコメント)

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

絞り込み :
はてなココの「ともだち」を表示します。
回答リクエストを送信したユーザーはいません