質問です

Excelのマクロでよければ、下記をお試しください。
なお、Windows環境なので、改行はCR+LFを1行として数えます。

Option Explicit

'拡張子を除く
Function GetFNameFromFStr(sFileName As String) As String
    Dim sFileStr As String
    Dim lFindPoint As Long
    Dim lStrLen As Long
    
    '文字列の右端から"."を検索し、左端からの位置を取得する
    lFindPoint = InStrRev(sFileName, ".")
    
    '拡張子を除いたファイル名の取得
    sFileStr = Left(sFileName, lFindPoint - 1)

    GetFNameFromFStr = sFileStr
End Function

'1ファイル処理
Function countLine(path As String, fname As String) As Long
    Dim buf As String
    Dim cnt As Long
    Dim dc As Object
    
    Set dc = CreateObject("Scripting.Dictionary")
    '行数カウント
    cnt = 0
    Open path & fname For Input As #1
    Do Until EOF(1)
        Line Input #1, buf
        cnt = cnt + 1
    Loop
    Close #1
    countLine = cnt
End Function

'ファイル探索＋ファイル名変更
Sub hogeConv(path As String, ext As String)
    Dim fcol As Object, re As Object
    Dim flist As Variant, remat As Variant
    Dim pat As String, fname As String
    Dim n As Long
    
    '処理対象ファイル探索＋処理実行
    Set fcol = CreateObject("Scripting.FileSystemObject").GetFolder(path).Files
    Set re = CreateObject("VBScript.RegExp")
    pat = "\." & ext & "$"
    With re
        .Pattern = pat
        .IgnoreCase = True
        .Global = True
        For Each flist In fcol
            fname = GetFNameFromFStr(flist.name)
            Set remat = .Execute(flist.name)
            If remat.Count > 0 Then
                n = countLine(path, flist.name)
                Name path & fname & "." & ext As path & fname & "_" & n & "." & ext
            End If
        Next flist
    End With
    Set re = Nothing
    Set fcol = Nothing
End Sub

Sub main()
    Call hogeConv("C:/test/", "txt")
End Sub