質問です

Question

inosisi

146

144もっと見る

100pt

コンピュータ

質問です

エクセルで文字が混じった数字の小計と合計を出す
関数かまたはマクロをお願いします

　　　　100件/50人
　　　　50件/25人
小計　　150件/75人

　　　　100件/50人
　　　　50件/25人
小計　　150件/75人

合計　　300件/150人

回答の条件

1人5回まで

登録：2013/06/14 10:57:12
終了：2013/06/14 13:56:07

※ 有料アンケート・ポイント付き質問機能は2023年2月28日に終了しました。

No.1

きゃづみぃ1353911982013/06/14 11:29:45

10pt


Function 合計(ar As Range)

    Dim c As Range
    
    Dim k1 As Long
    Dim k2 As Long
    
    k1 = 0
    k2 = 0
    
    For Each c In ar
        d = c.Value
        d1 = Replace(d, "人", "")
        d2 = Split(d1, "件/")
        
        k1 = k1 + d2(0)
        k2 = k2 + d2(1)
        
    Next c

    合計 = CStr(k1) & "件/" & CStr(k2) & "人"

End Function

標準モジュールに上記のソースを記述してください。

"件/"が区切り
"人"は最後にくっついているものとし、みな同一とします。
変更する場合は、この記述を変更してください。
"人"はなくてもいいですが、結果にはつきます。

使い方は
=合計(A1:A3)
というように合計したいセルの範囲を指定してください。

他3件のコメントを見る

小計の場合は、そのままでいいですが総合計の場合は、全部指定して、半分にすればいいでしょう。

2013/06/14 11:32:05

って簡単に半分にはできませんね。

2013/06/14 11:33:17



Function 合計半分(ar As Range)

    Dim c As Range
    
    Dim k1 As Long
    Dim k2 As Long
    
    k1 = 0
    k2 = 0
    
    For Each c In ar
        d = c.Value
        d1 = Replace(d, "人", "")
        d2 = Split(d1, "件/")
        
        k1 = k1 + d2(0)
        k2 = k2 + d2(1)
        
    Next c

    合計半分 = CStr(k1 / 2) & "件/" & CStr(k2 / 2) & "人"

End Function

総合計の場合は、上記を使ってください。
半分にするだけですが。

2013/06/14 11:35:11

ありがとうございます。
添付してあるのがサンプルデータです。
質問に書いてあるデータでは説明が不十分でした。
申し訳ございません。

2013/06/14 13:53:33

添付したものでも大丈夫だと思いますよ。

2013/06/14 14:04:26

コメントはまだありません

... a-kuma3さんのソースコードはキレイだなあ。 - VBA - はてなハイク 2013-06-14 13:09:09

http://q.hatena.ne.jp/1371175032#a1204385 a-kuma3さんのソースコードはキレイだなあ。
それ、うまいのか？ - たまには VBA 2013-06-17 18:07:20

たまには VBA VBA 嫌い。でも、使わざるを得なくなることもあるので、たまにはトレーニング。お題質問ですエクセルで文字が混じった数字の小計と合計を出す関数かまたはマクロをお願

「あの人に答えてほしい」「この質問はあの人が答えられそう」というときに、回答リクエストを送ってみてましょう。

これ以上回答リクエストを送信することはできません。制限について

リクエスト送信済

回答リクエストを送信したユーザーはいません

a-kuma3 · Accepted Answer · 2013-06-14T12:34:42+09:00

以下のコードを、標準モジュールに書いてください。

Function sum_item_person(ParamArray args() As Variant)

    Set re = CreateObject("VBScript.RegExp")
    re.Pattern = "(\d+)件/(\d+)人"
    re.Global = True

    item = 0
    person = 0
    
    For Each r In args
        For Each c In r
            Set remat = re.Execute(c.Value)
            If remat.Count > 0 Then
                item   = item   + remat(0).SubMatches(0)
                person = person + remat(0).SubMatches(1)
            end if
        Next c
    Next r

    sum_item_person = CStr(item) & "件/" & CStr(person) & "人"

End Function

関数の引数には、セルの範囲を指定します。
指定した範囲で、「(数字)件/(数字)人」となっているセルだけを合計の対象とします。
セル範囲を複数指定することも可能です。
例えば、こんな使い方ができます。

=sum_item_person(A1:B6, D10:F12)

シートのイメージだと、こんな感じです。

	A	B
1		72件/48人
2		25件/12人
3		3件/10人
4	小計	=sum_item_person(B1:B3)
5
6		22件/8人
7
8		34件/7人
9
10		14件/15人
11	小計	=sum_item_person(B6:B10)
12
13
14	合計	=sum_item_person(B4,B11)

a-kuma3 · Accepted Answer · 2013-06-14T12:34:42+09:00

以下のコードを、標準モジュールに書いてください。

Function sum_item_person(ParamArray args() As Variant)

    Set re = CreateObject("VBScript.RegExp")
    re.Pattern = "(\d+)件/(\d+)人"
    re.Global = True

    item = 0
    person = 0
    
    For Each r In args
        For Each c In r
            Set remat = re.Execute(c.Value)
            If remat.Count > 0 Then
                item   = item   + remat(0).SubMatches(0)
                person = person + remat(0).SubMatches(1)
            end if
        Next c
    Next r

    sum_item_person = CStr(item) & "件/" & CStr(person) & "人"

End Function

関数の引数には、セルの範囲を指定します。
指定した範囲で、「(数字)件/(数字)人」となっているセルだけを合計の対象とします。
セル範囲を複数指定することも可能です。
例えば、こんな使い方ができます。

=sum_item_person(A1:B6, D10:F12)

シートのイメージだと、こんな感じです。

	A	B
1		72件/48人
2		25件/12人
3		3件/10人
4	小計	=sum_item_person(B1:B3)
5
6		22件/8人
7
8		34件/7人
9
10		14件/15人
11	小計	=sum_item_person(B6:B10)
12
13
14	合計	=sum_item_person(B4,B11)

質問です

ベストアンサー

a-kuma3497321542013/06/14 12:34:42

その他の回答（1件）

きゃづみぃ1353911982013/06/14 11:29:45

a-kuma3497321542013/06/14 12:34:42ここでベストアンサー

コメント（0件)

この質問への反応（ブックマークコメント）

トラックバック