uwscを使っていまして、あるサイトのページを開いて、カーソル下のデーターを取得しています。

取ったデータをどう表示したいのかが分かりませんが、
今回の内容だと UWSC を使わなくともEXCEL だけでできそうな気がします。

Web からのデータ取得はフォームやタグから位置を特定して値をとるのが定石です。
今回の場合スポットには id="spot" が付いていますから、getElementByID で取得
出来ます。

VBAでスポット値をとるサンプルです。

Sub Sample()
　　MsgBox GetSpotValue()
End Sub

Function GetSpotValue()
　　Dim ie As Object
　　Set ie = CreateObject("InternetExplorer.Application")
    
　　ie.navigate "https://www.binary.com/d/trade.cgi?l=JA"
　　Do While ie.Busy Or ie.ReadyState < 4
　　　　DoEvents
　　Loop
　　GetSpotValue = ie.Document.getElementById("spot").innerText
　　ie.Quit
End Function

5分ごとにセルを更新するなら OnTime で記録する処理を呼び出せばこんな感じで
できるでしょうか。
http://officetanaka.net/excel/vba/tips/tips114.htm

Sub StartUpdate()
    Dim sp
    sp = GetSpotValue()
    Range("A1").Value = Now()
    Range("B1").Value = sp
    Range("C1").Value = sp
    Range("D1").Value = sp
    Range("E1").Value = sp
    Application.OnTime Application.Ceiling(Now, TimeValue("00:05:00")), "UpdateSpot"
End Sub

Sub StopUpdate()
    Application.OnTime Application.Ceiling(Now, TimeValue("00:05:00")), "UpdateSpot",,False
End Sub

Sub UpdateSpot()
    Dim sp
    sp = GetSpotValue()

    Range("A1").Value = Now()
    If sp > Range("C1").Value Then Range("C1").Value = sp
    If sp < Range("D1").Value Then Range("D1").Value = sp
    Range("E1").Value = sp

    Application.OnTime Application.Ceiling(Now + TimeValue("00:00:01"), TimeValue("00:05:00")), "UpdateSpot"
End Sub

Function GetSpotValue()
    Dim ie As Object
    Set ie = CreateObject("InternetExplorer.Application")
    
    ie.navigate "https://www.binary.com/d/trade.cgi?l=JA"
    Do While ie.Busy Or ie.ReadyState < 4
        DoEvents
    Loop
    GetSpotValue = ie.Document.getElementById("spot").innerText
    ie.Quit
End Function

IE の更新自体それほど高速ではないので、秒単位の処理はあまり意味がないと
思いますが、もともと EXCEL で何かしらの処理をしているようですから、
そこに組み込んだ方が効率がよさそうな気がします。




期待通り動くかどうかわかりませんが、毎秒のコード例です。

Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

'//----------------------------
Sub UpdatingSpot()
'//----------------------------
    Dim ie As Object
    Set ie = CreateObject("InternetExplorer.Application")
    
    Dim sp As Double
    With Worksheets("Sheet1")
    
        MsgBox "終了するときは A2 を消去してください。"
        .Range("A2").Value = "更新中"
        .Activate
        .Range("A2").Activate
        .Range("A1").NumberFormat = "hh:mm:ss"
        sp = GetSpotValue(ie, "https://www.binary.com/d/trade.cgi?l=JA")
        .Range("A1").Value = Now()
        .Range("B1").Value = sp
        .Range("C1").Value = sp
        .Range("D1").Value = sp
        .Range("E1").Value = sp
        
        Do While .Range("A2").Value <> ""
            Sleep 1000 '// msec
            sp = GetSpotValue(ie, "")
        '   sp = GetSpotValue(ie, "REFRESH") '// 毎回再読み込みするときは "REFRESH" を指定
            .Range("A1").Value = Now()
            If sp > .Range("C1").Value Then .Range("C1").Value = sp
            If sp < .Range("D1").Value Then .Range("D1").Value = sp
            .Range("E1").Value = sp
            DoEvents
            DoEvents
            DoEvents
        Loop
    End With
    ie.Quit
End Sub

'//----------------------------
Function GetSpotValue(ie, URL As String)
'//----------------------------
    Select Case UCase(URL)
        Case "REFRESH": ie.refresh
        Case "":
        Case Else
            ie.navigate URL
    End Select
    ie.visible = False
    Do While ie.Busy Or ie.ReadyState < 4
        DoEvents
    Loop
    
    GetSpotValue = ie.Document.getElementById("spot").innerText
End Function