《コンペ》　VBAマクロでサムチェックツール

チェックサムと言えばCRC32なので探し出しましたがスピードは遅いです。
たぶんライブラリ使ったid:cx20さんのにかなうのはないと思います。

※そのExcelファイルが置かれたパスを検出してくれるか、選択用のダイアログが出ると便利。
※マクロ実行する毎に次の行へ書き込んでくれると嬉しい。

この辺実装しました。
id:cx20さんのと組み合わせていただければ良いかと思います。

Option Explicit
Const FileNameSheet = "ファイル名"
Const FileNameCell = "A1"
Const HashStoreSheet = "サム値"
Const HashStoreColumn = "B"

Dim Crc32Table&(255)

' Mainマクロを実行する
Sub Main()
    Dim strFileName As String
    strFileName = GetFileName()
    Dim hash
    hash = GetCrc32FromFile(strFileName)
    hash = Hex(hash)
    'hash = GetFileHashMD5(strFileName)
    'hash = Mid(strHash, 24, 8)
    StoreResult hash
End Sub

Function GetFileName()
    ' カレントディレクトリをブックのあるフォルダにすることで絶対パス・相対パスどちらでも対応可能にする
    ' 参考： http://www.asahi-net.or.jp/~ef2o-inue/vba_o/sub05_110_140.html
    ChDrive ThisWorkbook.Path
    ChDir ThisWorkbook.Path
    ' 以下三種の取得方法
    ' GetFileName = Sheets(FileNameSheet).Range(FileNameCell).Value ' 特定シートの特定セルから得る
    GetFileName = Range(FileNameCell).Value ' 現在のシートの特定位置のセルから得る
    ' GetFileName = Selection.Value ' 選択中のセルから得る
End Function

Sub StoreResult(strResult)
    Sheets(HashStoreSheet).Cells(Rows.Count, HashStoreColumn).End(xlUp).Item(2).Value = strResult
    ' Rows.Count 行の最大値
    ' Cells(Rows.Count, "B") B列最終行のセル
    ' End(xlUp) 上方向(xlUp)でデータのある最初のセル(Ctrl+↑)
    ' 最終行のセル ＋ Ctrl+↑ ＝ データのある最後のセル
    ' Item(2) その下のセル（現在位置を(1)として上下に2番の位置）
End Sub

' 以下コピペ
' http://d.hatena.ne.jp/n7shi/20100910/1284112553
' https://code.msdn.microsoft.com/office/VBACRC-32-dad7d087
' Dim I%, J%, R&, R1&等参考
' http://www.atmarkit.co.jp/fdotnet/vb6tonet/vb6tonet30/vb6tonet30_01.html

Private Sub InitCrc32Table()
    Dim I%, J%, R&, R1&
    For I = 0 To 255
        R = I
        For J = 0 To 7
            R1 = R And 1
            R = (R - R1) / 2
            If R < 0 Then R = R - &H80000000
            If R1 Then R = R Xor &HEDB88320
        Next J
        Crc32Table(I) = R
    Next I
End Sub

Public Function GetCrc32FromFile&(Path$)
    Dim R&, I&, B As Byte, FL&
    If Crc32Table(255) = 0 Then InitCrc32Table
    FL = FileLen(Path)
    Open Path For Binary Lock Read As #2
    R = Not 0
    For I = 1 To FL
        Get #2, , B
        R = (Int(R / 256) And &HFFFFFF) Xor Crc32Table((R Xor B) And &HFF)
    Next I
    Close #2
    GetCrc32FromFile = Not R
End Function