Excelで指定した範囲の数字を含む行全てを削除したいです

G列のデータが数値という前提で。

Public Sub deleteRows()

    Const LOWER_LIMIT       As Long = 2
    Const UPPER_LIMIT       As Long = 4999

    Const TARGET_SHEET_NAME As String = "Sheet1"
    Const TARGET_COL        As String = "G"
    Const HEADER_ROWS       As Long = 0

    Dim ws          As Worksheet
    Dim r           As Range
    Dim lHeaderRow  As Long
    Dim lTargetCol  As Long
    Dim lBeginRow   As Long
    Dim lEndRow     As Long

    Set ws = ThisWorkbook.Worksheets(TARGET_SHEET_NAME)

    With ws
        If .AutoFilterMode = True Then
            'オートフィルタ適用中なら解除
            .AutoFilter.Range.AutoFilter
        End If

        lTargetCol = .Columns(TARGET_COL).Column

        If HEADER_ROWS = 0 Then
            'ヘッダー行が無ければ、オートフィルタ用に１行挿入
            lHeaderRow = 1
            .Rows(lHeaderRow).Insert
            .Cells(lHeaderRow, lTargetCol).Value = "DummyHeader"
        Else
            lHeaderRow = HEADER_ROWS
        End If

        lBeginRow = lHeaderRow + 1
        
        lEndRow = .Cells(ws.Rows.Count, lTargetCol).End(xlUp).Row

        Set r = .Range(.Cells(lHeaderRow, lTargetCol), .Cells(lEndRow, lTargetCol))
    End With

    'オートフィルタ適用
    r.AutoFilter Field:=1, Criteria1:=">=" & CStr(LOWER_LIMIT), Operator:=xlAnd, Criteria2:="<=" & CStr(UPPER_LIMIT)

    '対象行があれば行削除
    If r.SpecialCells(xlCellTypeVisible).Count > 1 Then
        Application.DisplayAlerts = False

        'ヘッダ行を除外して、表示されている行を削除
        ws.Range(ws.Cells(lBeginRow, lTargetCol), ws.Cells(lEndRow, lTargetCol)).SpecialCells(xlCellTypeVisible).Delete

        Application.DisplayAlerts = True
    End If

    'オートフィルタ解除
    r.AutoFilter

    Set r = Nothing

    If HEADER_ROWS = 0 Then
        'オートフィルタ用ダミーヘッダー削除
        ws.Rows(1).Delete
    End If

    Set ws = Nothing

End Sub

削除対象範囲が変わるなら、こういうのもありかと・・・

Public Sub deleteRows(ByVal lLowerLimit As Long, ByVal lUpperLimit As Long)

とか

Public Sub deleteRows(ByVal sTargetCol As String, ByVal lLowerLimit As Long, ByVal lUpperLimit As Long)