以下､ｻﾝﾌﾟﾙです｡
対象ﾌｫﾙﾀﾞは 01?n番 というわけではなく､ｶﾚﾝﾄﾃﾞｨﾚｸﾄﾘ直下のｻﾌﾞﾃﾞｨﾚｸﾄﾘを対象としてます｡
b.html が存在しない場合などで､ｴﾗｰになるかもしれません｡

' File : ChangePathName.vbs
' Usage : CScript ChangePathName.vbs
Option Explicit

Call Main()

Sub Main()
 Dim fso ' ﾌｧｲﾙｼｽﾃﾑｵﾌﾞｼﾞｪｸﾄ
 Set fso = CreateObject("Scripting.FileSystemObject")

 Dim folder
 Set folder = fso.GetFolder(".")
 
 Dim subFolder
 For Each subFolder In folder.SubFolders
 WScript.Echo "[" & subFolder.Name & "] ﾌｫﾙﾀﾞを処理中です｡"
 Call ChangePathName( fso, subFolder.Name )
 Next
End Sub

Sub ChangePathName( fso, strFolderName )
 Dim file  ' 対象ﾌｧｲﾙ
 Dim file2  ' 書き込み先ﾌｧｲﾙ
 Dim re  ' 正規表現ｵﾌﾞｼﾞｪｸﾄ
 Dim strOldText ' 置換前ﾃｷｽﾄ
 Dim strNewText ' 置換後ﾃｷｽﾄ
 Dim strFind  ' 検索文字列
 Dim strReplace ' 置換文字列
 
 Set file = fso.OpenTextFile( strFolderName & "/b.html")
 strOldText = file.ReadAll
 strFind = "<img src = """
 strReplace = "<img src = """ & strFolderName & "/"
 Set re = New RegExp
 re.Multiline = True
 re.Pattern = strFind
 re.Global = True
 strNewText = re.Replace(strOldText, strReplace)
 file.Close
 Set file2 = fso.CreateTextFile( strFolderName & ".html")
 file2.WriteLine (strNewText)
 file2.Close
End Sub

実行前のﾌｫﾙﾀﾞ構成

C:\home\edu\hatena\takanii\1362497323
└─a
 │ ChangePathName.vbs
 ├─01
 │ b.html
 ├─02
 │ b.html
 └─03
 b.html

実行方法｡ｺﾏﾝﾄﾞﾌﾟﾛﾝﾌﾟﾄにて以下を実行｡
(ﾌｫﾙﾀﾞが C:\home\edu\hatena\takanii\1362497323\a である場合)

C:\> CD C:\home\edu\hatena\takanii\1362497323\a [Enter]
C:\home\edu\hatena\takanii\1362497323\a> CScript ChangePathName.vbs [Enter]

Microsoft (R) Windows Script Host Version 5.8
Copyright (C) Microsoft Corporation 1996-2001. All rights reserved.

[01] ﾌｫﾙﾀﾞを処理中です｡
[02] ﾌｫﾙﾀﾞを処理中です｡
[03] ﾌｫﾙﾀﾞを処理中です｡
 :

実行後のﾌｫﾙﾀﾞ構成｡

C:\home\edu\hatena\takanii\1362497323
└─a
 │ ChangePathName.vbs
 │ 01.html
 │ 02.html
 │ 03.html
 ├─01
 │ b.html
 ├─02
 │ b.html
 └─03
 b.html

Dim objFile ' 対象ﾌｧｲﾙ
Dim oldText ' 置換前ﾃｷｽﾄ
Dim newText ' 置換後ﾃｷｽﾄ
Dim objFSO ' ﾌｧｲﾙｼｽﾃﾑｵﾌﾞｼﾞｪｸﾄ
Dim objRep ' 正規表現ｵﾌﾞｼﾞｪｸﾄ
Dim repText ' 置換後文字列
Dim objPath

Set objPath = CreateObject("Scripting.FileSystemObject").GetFolder(".")
Set objPath2 = CreateObject("Scripting.FileSystemObject").GetFolder("..")
p = right(objPath,len(objPath) - len(objPath2) -1)
Set objFSO = CreateObject("Scripting.FileSystemObject")
for a=1 to 99
b=right(cstr(100+a),2)
If objFso.FolderExists(objPath & "\" & b) Then
Set objFile = objFSO.OpenTextFile(b & "/b.html")
oldText = objFile.ReadAll
repText = "<img src = """ & b & "/"
Set objRep = New RegExp
objRep.Multiline = True
objRep.Pattern = "<img src = """
objRep.Global = True
newText = objRep.replace(oldText, repText)
objFile.Close
Set objFile = objFSO.CreateTextFile( b & ".html")
objFile.WriteLine (newText)
objFile.Close
end if
next

質問にあるｿｰｽをそのまま
>01?n番まで当てはめれるようなｽｸﾘﾌﾟﾄに
書き換えました｡

ちなみに 01からなので2桁ということで 最大99番までを想定しています｡

for a=1 to 99
の 99を 99以下にしてもらってもいいです｡