vbsの質問です hoge ﾌｫﾙﾀﾞの中に hoge |-01 |-02 |-03 |-04 |-･ |-･ |-･と数字の連番の名前がついたﾌｫﾙﾀﾞが入っていますその各数字ﾌｫﾙﾀﾞの中にa.htmlが入っ…

vbsの質問です
hoge ﾌｫﾙﾀﾞの中に
hoge
|-01
|-02
|-03
|-04
|-･
|-･
|-･
と数字の連番の名前がついたﾌｫﾙﾀﾞが入っています
その各数字ﾌｫﾙﾀﾞの中にa.htmlが入っています｡
その各a.htmlの中の末尾にある同じ文章をぶち込みたいです
その場合どの様にvbsを組めばよろしいでしょうか､教えてください｡
よろしくお願いします｡

こんな感じになります｡

targetFolderName = "D:\test\hoge"  ' ※ hoge ﾌｫﾙﾀﾞのﾊﾟｽ

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)
For Each folder In targetFolder.SubFolders
 For Each f In folder.Files
 If f.Name = "a.html" Then
 Set target = fs.OpenTextFile(f.Path, 8)  ' for append

 target.WriteLine "----------------"
 target.WriteLine "追加する文章"
 target.WriteLine "----------------"

 target.Close

 End If
 Next
Next

追記です｡

すみません､UTF8のﾃｷｽﾄﾌｧｲﾙに書き込んだら
追加する文章という文字が文字化けしてしまいました
文字化けせずにするにはどうすればいいでしょうか？

UTF-8 の場合には､以下のようにしてください｡

Set ado = WScript.CreateObject("adodb.stream")
ado.Type = 2
ado.Charset = "UTF-8"

Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set targetFolder = fs.getFolder(targetFolderName)
For Each folder In targetFolder.SubFolders
 For Each f In folder.Files
 If f.Name = "a.html" Then

 ado.Open
 ado.LoadFromFile f.Path
 txt = ado.ReadText
 ado.Close

 ado.Open
 ado.Position = 0
 ado.WriteText txt
 ado.WriteText "----------------" & vbCrLf
 ado.WriteText "追加する文章" & vbCrLf
 ado.WriteText "----------------" & vbCrLf
 ado.SaveToFile f.Path, 2
 ado.Close

 End If
 Next
Next

Set ado = Nothing