ピンポイントな回答には500ポイント差し上げます！

「コンボボックス」のオートコンプリート機能で実現する

１．Sheet1　に「コンボボックス」を追加します。

　　　　メニューの[表示]-[ツールバー]-[コントロールツールボックス]を表示します。

　　　　その中から、「コンボボックス」を選択し、Sheet1　に追加します。

２．ＶＢＡの記述

　　　　メニューの[ツール]-[マクロ]-[Visual Basic Editor]を表示します。

　　　　プロジェクトエクスプローラに表示されている[ThisWorkbook]をダブルクリックして、以下のコードを記述します。

'ワークブックのオープン時イベント

Private Sub Workbook_Open()

    'コンボボックスの表示内容を設定

    With Sheet1.ComboBox1

        .Font.Size = 8

        .Visible = False

        .AddItem "A1001 電卓"

        .AddItem "A1002 そろばん"

        .AddItem "A1103 りんご"

        .AddItem "A1104 みかん"

        .AddItem "A1205 桜"

        .AddItem "A1206 銀杏"

        .AddItem "A2001 スプーン"

        .AddItem "A2002 フォーク"

        .AddItem "A2103 ウサギ"

        .AddItem "A2104 たぬき"

        .AddItem "A2205 えび"

        .AddItem "A2206 かに"

    End With

End Sub

　　　　次に、プロジェクトエクスプローラに表示されている[Sheet1]をダブルクリックして、以下のコードを記述します。

'ワークシートのセルの選択を変更した場合のイベント

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    'Ａ列のみ、コンボボックスでの入力に設定してみます。

    If Target.Column = 1 Then 'Ａ列は１、Ｂ列は２・・・といった具合に指定

        If Target.Rows.Count = 1 And Target.Columns.Count = 1 Then

            With ComboBox1

                'コンボボックスの大きさをセルに合わせる

                .Width = Target.Cells(1, 1).Width

                .Height = Target.Cells(1, 1).Height

                .Top = Target.Top

                .Left = Target.Left

                'コンボボックスを表示

                .Value = ActiveCell.Value

                .Visible = True

                .Activate

            End With

        End If

    Else

       'コンボボックスを非表示

       ComboBox1.Visible = False

    End If

End Sub

'ワークシートの変更時イベント

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim i As Integer

    Dim hit As Boolean

    

    If Target.Column = 1 Then 'Ａ列は１、Ｂ列は２・・・といった具合に指定

        If Target.Rows.Count = 1 And Target.Columns.Count = 1 Then

            '入力規則チェック

            If Target.Value <> "" Then

                hit = False

                For i = 0 To ComboBox1.ListCount - 1

                    If ComboBox1.List(i) = ComboBox1.Value Then

                        hit = True

                    End If

                Next i

                If hit = False Then

                    MsgBox "入力規則に一致していません。", vbExclamation

                    Target.Value = ""

                    Exit Sub

                End If

            End If

        End If

    End If

End Sub

'コンボボックスの変更時イベント

Private Sub ComboBox1_Change()

    'コンボボックスの内容をセルにセット

    ActiveCell.Value = ComboBox1.Value

End Sub

'コンボボックスのキー押下時イベント

Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)

    If KeyCode = vbKeyReturn Or KeyCode = vbKeyTab Then

        '[Enter]、[Tab]キーが押されたら、次のセルへ移動

        ActiveCell.Activate

        SendKeys "{TAB}"

    End If

End Sub

３．以上で一旦、ワークブックを保存します。

４．ワークブックを再起動して、Sheet1のＡ列をクリックしてください

　　　　コンボボックスが表示されて、オートコンプリート入力が可能になります。

　　　　[Enter]、[Tab]キーの押下で、次の入力セルに移動します。