Excel2000を使用しています。セルに入力した絶対番地表示の数式の文字列データから、参照先のセルのアドレスを抜き出そうと考えています。自身のシート以外のシートを参照している場合には、シート名と参照先のセルアドレスの情報が必要です。参照が複数の場合には全ての参照情報を抜き出したいのです。参考になる情報やうまい実現方法がありましたら教えて下さい。

【方法】

・FormulaLocal　で数式を取得

・正規表現で、絶対参照の文字列を列挙

【サンプル】

Ａ１　=$B$1

Ａ２　=($B$1+$C$1)*$D$1

Ａ３　=Sheet2!$A$1+($B$1+$C$1)*$D$1*Sheet2!$C$2

・・・続く

などと入力して実行してください。

イミディエイトウィンドウに表示されます。

Option Explicit

Public Sub Test()

    Dim suSiki As String

    

    Range("A1").Select

    

    Do Until ActiveCell.Value = ""

        '数式を取得

        suSiki = ActiveCell.FormulaLocal

        '数式を書き出し

        Debug.Print Replace(ActiveCell.AddressLocal, "$", "") & "[" & suSiki & "]"

        '絶対参照を書き出し

        Call ExtractCellRef(suSiki)

        '次のセルへ

        ActiveCell.Offset(1, 0).Activate

    Loop

End Sub

Private Sub ExtractCellRef(ByVal suSiki As String)

    '正規表現オブジェクト

    Dim oRe, oMatch, oMatches

  

    '正規表現オブジェクトの参照をセット（新規作成）

    Set oRe = CreateObject("VBScript.RegExp")

    '正規表現オブジェクトのオプション設定

    With oRe

        .Global = True

        .IgnoreCase = True

    End With

    'マッチパターン作成

    oRe.Pattern = "(\$[A-Z]+\$[0-9]+)|([^=,\+\-\*\/]+!\$[A-Z]+\$[0-9]+)"

    

    '正規表現実行

    Set oMatches = oRe.Execute(suSiki)

    'マッチした全てに対して処理する

    For Each oMatch In oMatches

        Debug.Print vbTab & oMatch.Value

    Next

End Sub

※なお、正規表現のパターンはいささか自身がありません。