エクセルの質問です。

シートを追加して範囲という名前にしてください。

そこに、データを保存してみました。

Option Explicit

Private Sub CommandButton1_Click()
    Dim tenki As Range
    Dim str As String
    Dim WH As Worksheet
    Dim i As Long
    
    '範囲保存用のシートを指定
    Set WH = Worksheets("範囲")
    
    str = Application.InputBox(prompt:="集計名を入れてください", Title:="集計名", Type:=2)
    If str = "False" Then Exit Sub
    
    'キャンセルを選んだときのためエラートラップ
    On Error GoTo ErrNot
    Set tenki = Application.InputBox(prompt:="セル範囲を選択", Title:="セルを選択", Type:=8)
    On Error GoTo 0
    
    i = 1
    While WH.Cells(i, 1).Value <> ""
        i = i + 1
    Wend
    WH.Cells(i, 1).Value = str
    WH.Cells(i, 2).Value = tenki.Address
    
    ListBox1.AddItem (str)
    
    ListBox1.ListIndex = ListBox1.ListCount - 1
    
    Exit Sub
ErrNot:
End Sub

Private Sub ListBox1_Change()
    Dim WS As Worksheet
    Dim WH As Worksheet
    Dim r As Range
    Dim w As Worksheet
    Dim myRow As Long
    Dim tenki As Range
        
    If ListBox1.ListIndex = -1 Then Exit Sub
    
    '転記先のシートを指定
    Set WS = Worksheets("集計")
    
    '範囲保存用のシートを指定
    Set WH = Worksheets("範囲")
    
    WS.Cells.Clear
    myRow = 1
    For Each w In Worksheets
        If w.Name <> WS.Name And w.Name <> WH.Name Then
            Set tenki = w.Range(WH.Cells(ListBox1.ListIndex + 1, 2).Value)
            tenki.Copy
            WS.Cells(myRow, 1).PasteSpecial Paste:=xlAll, _
                Operation:=xlNone, SkipBlanks:=False, Transpose:=False
            WS.Cells(myRow, tenki.Column).ColumnWidth = tenki.ColumnWidth
            WS.Cells(myRow, tenki.Column).RowHeight = tenki.RowHeight

            myRow = myRow + tenki.Rows.Count

        End If
    Next w
    
    Application.CutCopyMode = False
    
    ListBox1.ListIndex = -1
End Sub

更にThisWorkbookのWorkbook_Openのところに次のように書けば、ブックを開いたときにリストボックスが戻ります。

Private Sub Workbook_Open()
    Dim i As Integer
    i = 1
    While Worksheets("範囲").Cells(i, 1).Value <> ""
        Worksheets("Sheet1").ListBox1.AddItem (Worksheets("範囲").Cells(i, 1).Value)
        i = i + 1
    Wend
End Sub

シート名とかはお使いの環境に合わせてください。

http://q.hatena.ne.jp/