Visual Basic 2008 Professional EditionのListView(もしくは入手が容易かつ、商用に組み込む場合に条件の少ない類似のコンポーネント)で質問です。

複数行や部分的な色を変更するにはオーナードローで行います。

オーナードローでやると、自分でアイコンの絵や、罫線、文字、フォーカス時の

色などは自分で描画する必要があります。

行の高さは、イメージリストのサイズで決まります。

描画はDrawItemイベントやDrawSubItemイベントで行います。

Public Class Form1

    Public Sub New()

        ' この呼び出しは、Windows フォーム デザイナで必要です。
        InitializeComponent()

        ' InitializeComponent() 呼び出しの後で初期化を追加します。

        Me.ListView1.View = View.Details
        Me.ListView1.OwnerDraw = True


    End Sub


    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim files As String() = System.IO.Directory.GetFiles( _
            System.Environment.GetFolderPath(Environment.SpecialFolder.Personal), "*", System.IO.SearchOption.TopDirectoryOnly)

        Dim file As String
        Dim imageList As New ImageList()
        Me.ListView1.Columns.Add("ファイル名", 200)
        Me.ListView1.SmallImageList = imageList
        Dim width As Integer = 48
        Dim height As Integer = 48

        imageList.ImageSize = New Size(width, height)

        Dim idx As Integer = 0

        For Each file In files
            Dim appIcon As Icon
            appIcon = System.Drawing.Icon.ExtractAssociatedIcon(file)
            imageList.Images.Add(appIcon.ToBitmap())

            Dim fileName As String
            fileName = System.IO.Path.GetFileName(file)
            ' リストビューアイテム作成
            Dim item As ListViewItem = New ListViewItem(fileName)

            Me.ListView1.Items.Add(item)
            Me.ListView1.Items(idx).ImageIndex = idx

            idx += 1
        Next


    End Sub

    Private Sub ListView1_DrawItem(ByVal sender As Object, ByVal e As System.Windows.Forms.DrawListViewItemEventArgs) Handles ListView1.DrawItem
        Dim g As Graphics
        g = e.Graphics
        Dim drawString As String
        Dim drawString2 As String
        drawString = "AAA" + vbCrLf + "BBB"
        drawString2 = "CCC" + e.ItemIndex.ToString

        Dim rect As Rectangle
        rect = e.Bounds
        '背景描画
        If e.Item.Selected = True Then
            g.FillRectangle(Brushes.SkyBlue, rect)
        Else
            g.FillRectangle(Brushes.Yellow, rect)
        End If
        '罫線の描画
        Using pen As New Pen(Color.Gray)
            g.DrawRectangle(pen, rect)
        End Using
        '文字の描画位置
        rect.Location = New Point(e.Bounds.Left + e.Item.ImageList.Images(e.ItemIndex).Width, e.Bounds.Top)
        '文字を書く
        g.DrawString(drawString, Me.ListView1.Font, Brushes.Black, rect)

        Dim stringSize As SizeF = g.MeasureString(drawString, Me.ListView1.Font)
        '文字を書く
        g.DrawString(drawString2, Me.ListView1.Font, Brushes.Red, rect.Location.X, rect.Location.Y + stringSize.Height)

        g.DrawImage(e.Item.ImageList.Images(e.ItemIndex), e.Bounds.Location)
    End Sub

End Class