業務でサイボウズを使いはじめました。

API でやる方がスマートだと思いますが、とりあえず IE の実装例です。

発言したい掲示板の書き込み画面を一度手動で表示し、その時のURLを★の次行に

書いて実行してください。

• タイトルをB1から拾って記述しているので、変更したいときは ☆1の次行を変更してください。
• 「掲示する」を手動でクリックしたい場合は☆3の次行をコメントアウトしてください。

Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

'// ★掲示を書き込む URL
Const boardWriteURL = "http://192.168.1.1/cgi-bin/cbgrn/grn.exe/bulletin/send?cid=4"
Const WAIT_TIME_OUT = 15

Sub SendBoardMessage()
    Dim objIE
    Set objIE = CreateObject("InternetExplorer.Application")

    objIE.Navigate boardWriteURL
    objIE.Visible = True

    If WaitReadyState(objIE, "掲示を書き込む") = False Then
        MsgBox "掲示板が表示できません"
        objIE.Quit
        Exit Sub
    End If

'//☆1 タイトルを入れる
    objIE.document.getElementsByName("title")(0).Value = Range("B1").Value
    MsgBox "タイトルを書きました。"
    Sleep 300
'//☆2 内容を入れる
    objIE.document.getElementsByName("data")(0).Value = Range("B2").Value
    MsgBox "本文を書きました。"
    Sleep 300
'//☆3 「掲示する」をクリック
'//    objIE.document.getElementsByName("send")(0).Click
'// ボタンの名前で検索
    Dim objs, o
    Set objs = objIE.document.getElementsByTagName("input")
    For Each o In objs
        If o.Value = "書き込む" Then
            o.Click
            MsgBox "保存しました。"
            Exit Sub
        End If
    Next
    MsgBox "保存ボタンが見つかりませんでした。"
End Sub


Function WaitReadyState(objIE, keyWord) As Boolean
    Dim startTime
    startTime = Now
    Do While True
        If objIE.Busy = False And objIE.readyState = 4 Then
            If InStr(objIE.document.Body.innerText, keyWord) > 0 Then
                WaitReadyState = True
                Exit Function
            End If
        End If
        If DateDiff("s", startTime, Now) > WAIT_TIME_OUT Then
            WaitReadyState = False
            Exit Function
        End If
        DoEvents
        Sleep 50
    Loop
End Function

参考

http://www.ken3.org/cgi-bin/group/vba_ie.asp