私の苦手なVBAを教えてください。

fuentebellaさんのコメントにあるようにVBAではなく条件付書式で可能なようです。

条件付書式の使い方

http://www.eurus.dti.ne.jp/~yoneyama/Excel/jyo-syo.html

具体的には

Ｆ５セルとＦ６セルの条件付書式を

数式が　=F5<>""

書式を水色に。

Ｆ５とＦ６を選択してＪ列までコピーし、更に下のにもコピーします。

名前のＡ５セルの条件付書式は

数式が　=DATE(YEAR(K5),MONTH(K5)-3,DAY(K5))>TODAY()

書式を青色。

追加を押して条件２に、

数式が　=DATE(YEAR(K5),MONTH(K5)-3,DAY(K5))<=TODAY()

書式をローズに。

結合したＡ５セルを下にコピーすれば完成です。

質問の意図を自分なりに解釈しましたが間違っていたら、ご指摘ください。

対象のシートのタブを右クリックし、「コードの表示」で表示される部分に下記のコードをコピーして

実行してみてください。

下記のように動作します。

• A列（7行目以降）を変更（名前を入力）すると、その行（２行）を対象に条件付き書式を設定します。
• A列はK列の日付の3ヶ月前（日にちは無視）になると色が付きます。K列は日付を入力してください。
• F～J列に対して

　　　上段＝空白、下段＝空白・・・青

　　　上段≠空白、下段＝空白・・・元のセルの色（たぶん白？）

　　　上段≠空白、下段≠空白・・・水色

色は下記を参照ください。

http://homepage2.nifty.com/miyuki-t/html/excelcolor.html

'// 色の定義
Const CELL_COLOR_BLANK = 5
Const CELL_COLOR_NAME = 38
Const CELL_COLOR_DONE = 20

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim r As Range
    For Each r In Target
        If r.Column = 1 And r.Row > 6 And r.Row Mod 2 = 1 Then
            setConditionallyForm r.Row
        End If
    Next
End Sub


Sub setConditionallyForm(rr As Long)
'// A列に設定
    With Cells(rr, "A").Resize(2, 1)
        .FormatConditions.Delete
        .FormatConditions.Add Type:=xlExpression, _
             Formula1:="=AND(RC11<>"""",(YEAR(TODAY())*12+MONTH(TODAY()))>(YEAR(RC11)*12+MONTH(RC11)-3))"
        .FormatConditions(1).Interior.ColorIndex = CELL_COLOR_NAME
    End With

'// F から5列（J列）まで設定
    With Cells(rr, "F").Resize(1, 5)
        .FormatConditions.Delete
        .FormatConditions.Add Type:=xlExpression, _
             Formula1:="=AND(RC="""",R[1]C="""")"
        .FormatConditions(1).Interior.ColorIndex = CELL_COLOR_BLANK
        
        .FormatConditions.Add Type:=xlExpression, _
             Formula1:="=AND(RC<>"""",R[1]C<>"""")"
        .FormatConditions(2).Interior.ColorIndex = CELL_COLOR_DONE
    End With
    
    With Cells(rr + 1, "F").Resize(1, 5)
        .FormatConditions.Delete
        .FormatConditions.Add Type:=xlExpression, _
             Formula1:="=AND(RC="""",R[-1]C="""")"
        .FormatConditions(1).Interior.ColorIndex = CELL_COLOR_BLANK
        
        .FormatConditions.Add Type:=xlExpression, _
             Formula1:="=AND(RC<>"""",R[-1]C<>"""")"
        .FormatConditions(2).Interior.ColorIndex = CELL_COLOR_DONE
    End With
End Sub

不明な点はコメントにて対応します。